Initial Commit

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Graphics/DepthSort/DepthSort.pde

@@ -0,0 +1,50 @@
+// Depth sorting example by Jakub Valtar 
+// https://github.com/JakubValtar
+
+void setup() {
+  size(640, 720, P3D);
+  colorMode(HSB, 100, 100, 100, 100);
+    
+  frameRate(60);
+}
+ 
+void draw() {    
+    //beginRaw(PDF, "output" + frameCount + ".pdf");
+    
+  if (!mousePressed) {
+    hint(ENABLE_DEPTH_SORT);
+  } else {
+    hint(DISABLE_DEPTH_SORT);
+  }
+    
+  noStroke();
+  
+  background(0);
+ 
+  translate(width/2, height/2, -300);
+  scale(2);
+    
+  int rot = frameCount;
+
+  rotateZ(radians(90));
+  rotateX(radians(rot/60.0f * 10));
+  rotateY(radians(rot/60.0f * 30));
+ 
+  blendMode(ADD);
+    
+  for (int i = 0; i < 100; i++) {
+    fill(map(i % 10, 0, 10, 0, 100), 100, 100, 30);
+ 
+    beginShape(TRIANGLES);
+    vertex(200, 50, -50);
+    vertex(100, 100, 50);
+    vertex(100, 0, 20);
+    endShape();
+ 
+    rotateY(radians(270.0f/100));
+  }
+    
+  //endRaw();
+  
+  if (frameCount % 30 == 0) println(frameRate);
+}  

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Graphics/LowLevelGLVboInterleaved/LowLevelGLVboInterleaved.pde

@@ -0,0 +1,163 @@
+// Draws a triangle using low-level OpenGL calls.
+
+import java.nio.*;
+
+PShader sh;
+
+float[] attribs;
+
+FloatBuffer attribBuffer;
+
+int attribVboId;
+
+final static int VERT_CMP_COUNT = 4; // vertex component count (x, y, z, w) -> 4
+final static int CLR_CMP_COUNT = 4;  // color component count (r, g, b, a) -> 4
+
+public void setup() {
+  size(640, 360, P3D);
+
+  // Loads a shader to render geometry w/out
+  // textures and lights.
+  sh = loadShader("frag.glsl", "vert.glsl");
+
+  attribs = new float[24];
+  attribBuffer = allocateDirectFloatBuffer(24);
+
+  PGL pgl = beginPGL();
+
+  IntBuffer intBuffer = IntBuffer.allocate(1);
+  pgl.genBuffers(1, intBuffer);
+
+  attribVboId = intBuffer.get(0);
+
+  endPGL();
+}
+
+public void draw() {
+
+  PGL pgl = beginPGL();
+
+  background(0);
+
+  // The geometric transformations will be automatically passed
+  // to the shader.
+  rotate(frameCount * 0.01f, width, height, 0);
+
+  updateGeometry();
+  sh.bind();
+
+  // get "vertex" attribute location in the shader
+  final int vertLoc = pgl.getAttribLocation(sh.glProgram, "vertex");
+  // enable array for "vertex" attribute
+  pgl.enableVertexAttribArray(vertLoc);
+
+  // get "color" attribute location in the shader
+  final int colorLoc = pgl.getAttribLocation(sh.glProgram, "color");
+  // enable array for "color" attribute
+  pgl.enableVertexAttribArray(colorLoc);
+
+
+  /*
+    BUFFER LAYOUT from updateGeometry()
+
+    xyzwrgbaxyzwrgbaxyzwrgba...
+
+    |v1       |v2       |v3       |...
+    |0   |4   |8   |12  |16  |20  |...
+    |xyzw|rgba|xyzw|rgba|xyzw|rgba|...
+
+    stride (values per vertex) is 8 floats
+    vertex offset is 0 floats (starts at the beginning of each line)
+    color offset is 4 floats (starts after vertex coords)
+
+       |0   |4   |8
+    v1 |xyzw|rgba|
+    v2 |xyzw|rgba|
+    v3 |xyzw|rgba|
+       |...
+   */
+  final int stride       = (VERT_CMP_COUNT + CLR_CMP_COUNT) * Float.BYTES;
+  final int vertexOffset =                                0 * Float.BYTES;
+  final int colorOffset  =                   VERT_CMP_COUNT * Float.BYTES;
+
+  // bind VBO
+  pgl.bindBuffer(PGL.ARRAY_BUFFER, attribVboId);
+  // fill VBO with data
+  pgl.bufferData(PGL.ARRAY_BUFFER, Float.BYTES * attribs.length, attribBuffer, PGL.DYNAMIC_DRAW);
+  // associate currently bound VBO with "vertex" shader attribute
+  pgl.vertexAttribPointer(vertLoc, VERT_CMP_COUNT, PGL.FLOAT, false, stride, vertexOffset);
+  // associate currently bound VBO with "color" shader attribute
+  pgl.vertexAttribPointer(colorLoc, CLR_CMP_COUNT, PGL.FLOAT, false, stride, colorOffset);
+  // unbind VBO
+  pgl.bindBuffer(PGL.ARRAY_BUFFER, 0);
+
+
+  pgl.drawArrays(PGL.TRIANGLES, 0, 3);
+
+
+  // disable arrays for attributes before unbinding the shader
+  pgl.disableVertexAttribArray(vertLoc);
+  pgl.disableVertexAttribArray(colorLoc);
+
+  sh.unbind();
+
+  endPGL();
+}
+
+// Triggers a crash when closing the output window using the close button
+//public void dispose() {
+//  PGL pgl = beginPGL();
+
+//  IntBuffer intBuffer = IntBuffer.allocate(1);
+//  intBuffer.put(attribVboId);
+//  intBuffer.rewind();
+//  pgl.deleteBuffers(1, intBuffer);
+
+//  endPGL();
+//}
+
+void updateGeometry() {
+  // Vertex 1
+  attribs[0] = 0;
+  attribs[1] = 0;
+  attribs[2] = 0;
+  attribs[3] = 1;
+
+  // Color 1
+  attribs[4] = 1;
+  attribs[5] = 0;
+  attribs[6] = 0;
+  attribs[7] = 1;
+
+  // Vertex 2
+  attribs[8] = width/2;
+  attribs[9] = height;
+  attribs[10] = 0;
+  attribs[11] = 1;
+
+  // Color 2
+  attribs[12] = 0;
+  attribs[13] = 1;
+  attribs[14] = 0;
+  attribs[15] = 1;
+
+  // Vertex 3
+  attribs[16] = width;
+  attribs[17] = 0;
+  attribs[18] = 0;
+  attribs[19] = 1;
+
+  // Color 3
+  attribs[20] = 0;
+  attribs[21] = 0;
+  attribs[22] = 1;
+  attribs[23] = 1;
+
+  attribBuffer.rewind();
+  attribBuffer.put(attribs);
+  attribBuffer.rewind();
+}
+
+FloatBuffer allocateDirectFloatBuffer(int n) {
+  return ByteBuffer.allocateDirect(n * Float.BYTES).order(ByteOrder.nativeOrder()).asFloatBuffer();
+}

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Graphics/LowLevelGLVboInterleaved/data/frag.glsl

@@ -0,0 +1,30 @@
+/*
+  Part of the Processing project - http://processing.org
+
+  Copyright (c) 2011-12 Ben Fry and Casey Reas
+
+  This library is free software; you can redistribute it and/or
+  modify it under the terms of the GNU Lesser General Public
+  License version 2.1 as published by the Free Software Foundation.
+
+  This library is distributed in the hope that it will be useful,
+  but WITHOUT ANY WARRANTY; without even the implied warranty of
+  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+  Lesser General Public License for more details.
+
+  You should have received a copy of the GNU Lesser General
+  Public License along with this library; if not, write to the
+  Free Software Foundation, Inc., 59 Temple Place, Suite 330,
+  Boston, MA  02111-1307  USA
+ */
+
+#ifdef GL_ES
+precision mediump float;
+precision mediump int;
+#endif
+
+varying vec4 vertColor;
+
+void main() {
+  gl_FragColor = vertColor;
+}

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Graphics/LowLevelGLVboInterleaved/data/vert.glsl

@@ -0,0 +1,31 @@
+/*
+  Part of the Processing project - http://processing.org
+
+  Copyright (c) 2011-12 Ben Fry and Casey Reas
+
+  This library is free software; you can redistribute it and/or
+  modify it under the terms of the GNU Lesser General Public
+  License version 2.1 as published by the Free Software Foundation.
+
+  This library is distributed in the hope that it will be useful,
+  but WITHOUT ANY WARRANTY; without even the implied warranty of
+  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+  Lesser General Public License for more details.
+
+  You should have received a copy of the GNU Lesser General
+  Public License along with this library; if not, write to the
+  Free Software Foundation, Inc., 59 Temple Place, Suite 330,
+  Boston, MA  02111-1307  USA
+ */
+
+uniform mat4 transform;
+
+attribute vec4 vertex;
+attribute vec4 color;
+
+varying vec4 vertColor;
+
+void main() {
+  gl_Position = transform * vertex;    
+  vertColor = color;
+}

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Graphics/LowLevelGLVboSeparate/LowLevelGLVboSeparate.pde

@@ -0,0 +1,188 @@
+// Draws a triangle using low-level OpenGL calls.
+
+import java.nio.*;
+
+PShader sh;
+
+float[] vertices;
+float[] colors;
+
+FloatBuffer vertexBuffer;
+FloatBuffer colorBuffer;
+
+int vertexVboId;
+int colorVboId;
+
+final static int VERT_CMP_COUNT = 4; // vertex component count (x, y, z, w) -> 4
+final static int CLR_CMP_COUNT = 4;  // color component count (r, g, b, a) -> 4
+
+public void setup() {
+  size(640, 360, P3D);
+
+  // Loads a shader to render geometry w/out
+  // textures and lights.
+  sh = loadShader("frag.glsl", "vert.glsl");
+
+  vertices = new float[12];
+  colors = new float[12];
+
+  vertexBuffer = allocateDirectFloatBuffer(12);
+  colorBuffer = allocateDirectFloatBuffer(12);
+
+  PGL pgl = beginPGL();
+
+  // allocate buffer big enough to get all VBO ids back
+  IntBuffer intBuffer = IntBuffer.allocate(2);
+  pgl.genBuffers(2, intBuffer);
+
+  vertexVboId = intBuffer.get(0);
+  colorVboId = intBuffer.get(1);
+
+  endPGL();
+}
+
+public void draw() {
+
+  PGL pgl = beginPGL();
+
+  background(0);
+
+  // The geometric transformations will be automatically passed
+  // to the shader.
+  rotate(frameCount * 0.01f, width, height, 0);
+
+  updateGeometry();
+  sh.bind();
+
+  // get "vertex" attribute location in the shader
+  final int vertLoc = pgl.getAttribLocation(sh.glProgram, "vertex");
+  // enable array for "vertex" attribute
+  pgl.enableVertexAttribArray(vertLoc);
+
+  // get "color" attribute location in the shader
+  final int colorLoc = pgl.getAttribLocation(sh.glProgram, "color");
+  // enable array for "color" attribute
+  pgl.enableVertexAttribArray(colorLoc);
+
+  /*
+    BUFFER LAYOUT from updateGeometry()
+
+    Vertex buffer:
+
+      xyzwxyzwxyzw...
+
+      |v1  |v2  |v3  |...
+      |0   |4   |8   |...
+      |xyzw|xyzw|xyzw|...
+
+
+    Color buffer:
+
+      rgbargbargba...
+
+      |v1  |v2  |v3  |...
+      |0   |4   |8   |...
+      |rgba|rgba|rgba|...
+
+    stride (values per vertex) is 4 floats in both cases
+    vertex offset is 0 floats in both cases
+   */
+  final int vertexStride = VERT_CMP_COUNT * Float.BYTES;
+  final int colorStride  =  CLR_CMP_COUNT * Float.BYTES;
+  final int vertexOffset =              0 * Float.BYTES;
+  final int colorOffset  =              0 * Float.BYTES;
+
+
+  { // VERTEX
+    // bind VBO
+    pgl.bindBuffer(PGL.ARRAY_BUFFER, vertexVboId);
+    // fill VBO with data
+    pgl.bufferData(PGL.ARRAY_BUFFER, Float.BYTES * vertices.length, vertexBuffer, PGL.DYNAMIC_DRAW);
+    // associate currently bound VBO with shader attribute
+    pgl.vertexAttribPointer(vertLoc, VERT_CMP_COUNT, PGL.FLOAT, false, vertexStride, vertexOffset);
+  }
+
+  { // COLOR
+    // bind VBO
+    pgl.bindBuffer(PGL.ARRAY_BUFFER, colorVboId);
+    // fill bound VBO with data
+    pgl.bufferData(PGL.ARRAY_BUFFER, Float.BYTES * colors.length, colorBuffer, PGL.DYNAMIC_DRAW);
+    // associate currently bound VBO with shader attribute
+    pgl.vertexAttribPointer(colorLoc, CLR_CMP_COUNT, PGL.FLOAT, false, colorStride, colorOffset);
+  }
+
+  // unbind VBOs
+  pgl.bindBuffer(PGL.ARRAY_BUFFER, 0);
+
+
+  pgl.drawArrays(PGL.TRIANGLES, 0, 3);
+
+
+  // disable arrays for attributes before unbinding the shader
+  pgl.disableVertexAttribArray(vertLoc);
+  pgl.disableVertexAttribArray(colorLoc);
+
+  sh.unbind();
+
+  endPGL();
+}
+
+// Triggers a crash when closing the output window using the close button
+//public void dispose() {
+//  PGL pgl = beginPGL();
+
+//  IntBuffer intBuffer = IntBuffer.allocate(2);
+//  intBuffer.put(vertexVboId);
+//  intBuffer.put(colorVboId);
+//  intBuffer.rewind();
+//  pgl.deleteBuffers(2, intBuffer);
+
+//  endPGL();
+//}
+
+void updateGeometry() {
+  // Vertex 1
+  vertices[0] = 0;
+  vertices[1] = 0;
+  vertices[2] = 0;
+  vertices[3] = 1;
+
+  colors[0] = 1;
+  colors[1] = 0;
+  colors[2] = 0;
+  colors[3] = 1;
+
+  // Vertex 2
+  vertices[4] = width/2;
+  vertices[5] = height;
+  vertices[6] = 0;
+  vertices[7] = 1;
+
+  colors[4] = 0;
+  colors[5] = 1;
+  colors[6] = 0;
+  colors[7] = 1;
+
+  // Vertex 3
+  vertices[8] = width;
+  vertices[9] = 0;
+  vertices[10] = 0;
+  vertices[11] = 1;
+
+  colors[8] = 0;
+  colors[9] = 0;
+  colors[10] = 1;
+  colors[11] = 1;
+
+  vertexBuffer.rewind();
+  vertexBuffer.put(vertices);
+  vertexBuffer.rewind();
+
+  colorBuffer.rewind();
+  colorBuffer.put(colors);
+  colorBuffer.rewind();
+}
+
+FloatBuffer allocateDirectFloatBuffer(int n) {
+  return ByteBuffer.allocateDirect(n * Float.BYTES).order(ByteOrder.nativeOrder()).asFloatBuffer();
+}

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Graphics/LowLevelGLVboSeparate/data/frag.glsl

@@ -0,0 +1,30 @@
+/*
+  Part of the Processing project - http://processing.org
+
+  Copyright (c) 2011-12 Ben Fry and Casey Reas
+
+  This library is free software; you can redistribute it and/or
+  modify it under the terms of the GNU Lesser General Public
+  License version 2.1 as published by the Free Software Foundation.
+
+  This library is distributed in the hope that it will be useful,
+  but WITHOUT ANY WARRANTY; without even the implied warranty of
+  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+  Lesser General Public License for more details.
+
+  You should have received a copy of the GNU Lesser General
+  Public License along with this library; if not, write to the
+  Free Software Foundation, Inc., 59 Temple Place, Suite 330,
+  Boston, MA  02111-1307  USA
+ */
+
+#ifdef GL_ES
+precision mediump float;
+precision mediump int;
+#endif
+
+varying vec4 vertColor;
+
+void main() {
+  gl_FragColor = vertColor;
+}

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Graphics/LowLevelGLVboSeparate/data/vert.glsl

@@ -0,0 +1,31 @@
+/*
+  Part of the Processing project - http://processing.org
+
+  Copyright (c) 2011-12 Ben Fry and Casey Reas
+
+  This library is free software; you can redistribute it and/or
+  modify it under the terms of the GNU Lesser General Public
+  License version 2.1 as published by the Free Software Foundation.
+
+  This library is distributed in the hope that it will be useful,
+  but WITHOUT ANY WARRANTY; without even the implied warranty of
+  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+  Lesser General Public License for more details.
+
+  You should have received a copy of the GNU Lesser General
+  Public License along with this library; if not, write to the
+  Free Software Foundation, Inc., 59 Temple Place, Suite 330,
+  Boston, MA  02111-1307  USA
+ */
+
+uniform mat4 transform;
+
+attribute vec4 vertex;
+attribute vec4 color;
+
+varying vec4 vertColor;
+
+void main() {
+  gl_Position = transform * vertex;    
+  vertColor = color;
+}

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Graphics/MeshTweening/MeshTweening.pde

@@ -0,0 +1,50 @@
+// Use of custom vertex attributes.
+// Inspired by 
+// http://pyopengl.sourceforge.net/context/tutorials/shader_4.html
+
+PShader sh;
+PShape grid;
+
+void setup() {
+  size(640, 360, P3D);
+  sh = loadShader("frag.glsl", "vert.glsl");
+  shader(sh);
+  
+  grid = createShape();
+  grid.beginShape(QUADS);
+  grid.noStroke();  
+  grid.fill(150);  
+  float d = 10;
+  for (int x = -500; x < 500; x += d) {
+    for (int y = -500; y < 500; y += d) {
+      grid.fill(255 * noise(x, y));
+      grid.attribPosition("tweened", x, y, 100 * noise(x, y));
+      grid.vertex(x, y, 0);
+     
+      grid.fill(255 * noise(x + d, y));
+      grid.attribPosition("tweened", x + d, y, 100 * noise(x + d, y));
+      grid.vertex(x + d, y, 0);
+      
+      grid.fill(255 * noise(x + d, y + d));
+      grid.attribPosition("tweened", x + d, y + d, 100 * noise(x + d, y + d)); 
+      grid.vertex(x + d, y + d, 0);
+      
+      grid.fill(255 * noise(x, y + d));
+      grid.attribPosition("tweened", x, y + d, 100 * noise(x, y + d));
+      grid.vertex(x, y + d, 0);    
+    }
+  }
+  grid.endShape();  
+}
+
+void draw() {
+  background(255);
+  
+  sh.set("tween", map(mouseX, 0, width, 0, 1));
+  
+  translate(width/2, height/2, 0);
+  rotateX(frameCount * 0.01);
+  rotateY(frameCount * 0.01);
+  
+  shape(grid);
+}

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Graphics/MeshTweening/data/frag.glsl

@@ -0,0 +1,5 @@
+varying vec4 vertColor;
+
+void main() {
+  gl_FragColor = vertColor;
+}

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Graphics/MeshTweening/data/vert.glsl

@@ -0,0 +1,14 @@
+uniform mat4 transformMatrix;
+uniform float tween;
+
+attribute vec4 position;
+attribute vec4 tweened;
+attribute vec4 color;
+
+varying vec4 vertColor;
+
+void main() {
+  gl_Position = transformMatrix * ((1.0 - tween) * position + tween * tweened);
+    
+  vertColor = color;
+}

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Graphics/Particles/Particle.pde

@@ -0,0 +1,59 @@
+class Particle {
+
+  PVector velocity;
+  float lifespan = 255;
+  
+  PShape part;
+  float partSize;
+  
+  PVector gravity = new PVector(0,0.1);
+
+
+  Particle() {
+    partSize = random(10,60);
+    part = createShape();
+    part.beginShape(QUAD);
+    part.noStroke();
+    part.texture(sprite);
+    part.normal(0, 0, 1);
+    part.vertex(-partSize/2, -partSize/2, 0, 0);
+    part.vertex(+partSize/2, -partSize/2, sprite.width, 0);
+    part.vertex(+partSize/2, +partSize/2, sprite.width, sprite.height);
+    part.vertex(-partSize/2, +partSize/2, 0, sprite.height);
+    part.endShape();
+    
+    rebirth(width/2,height/2);
+    lifespan = random(255);
+  }
+
+  PShape getShape() {
+    return part;
+  }
+  
+  void rebirth(float x, float y) {
+    float a = random(TWO_PI);
+    float speed = random(0.5,4);
+    velocity = new PVector(cos(a), sin(a));
+    velocity.mult(speed);
+    lifespan = 255;   
+    part.resetMatrix();
+    part.translate(x, y); 
+  }
+  
+  boolean isDead() {
+    if (lifespan < 0) {
+     return true;
+    } else {
+     return false;
+    } 
+  }
+  
+
+  public void update() {
+    lifespan = lifespan - 1;
+    velocity.add(gravity);
+    
+    part.setTint(color(255,lifespan));
+    part.translate(velocity.x, velocity.y);
+  }
+}

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Graphics/Particles/ParticleSystem.pde

@@ -0,0 +1,36 @@
+class ParticleSystem {
+  ArrayList<Particle> particles;
+
+  PShape particleShape;
+
+  ParticleSystem(int n) {
+    particles = new ArrayList<Particle>();
+    particleShape = createShape(PShape.GROUP);
+
+    for (int i = 0; i < n; i++) {
+      Particle p = new Particle();
+      particles.add(p);
+      particleShape.addChild(p.getShape());
+    }
+  }
+
+  void update() {
+    for (Particle p : particles) {
+      p.update();
+    }
+  }
+
+  void setEmitter(float x, float y) {
+    for (Particle p : particles) {
+      if (p.isDead()) {
+        p.rebirth(x, y);
+      }
+    }
+  }
+
+  void display() {
+
+    shape(particleShape);
+  }
+}
+

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Graphics/Particles/Particles.pde

@@ -0,0 +1,31 @@
+// Particles, by Daniel Shiffman.
+
+ParticleSystem ps;
+PImage sprite;  
+
+void setup() {
+  size(1024, 768, P2D);
+  orientation(LANDSCAPE);
+  sprite = loadImage("sprite.png");
+  ps = new ParticleSystem(10000);
+
+  // Writing to the depth buffer is disabled to avoid rendering
+  // artifacts due to the fact that the particles are semi-transparent
+  // but not z-sorted.
+  hint(DISABLE_DEPTH_MASK);
+} 
+
+void draw () {
+  background(0);
+  ps.update();
+  ps.display();
+  
+  ps.setEmitter(mouseX,mouseY);
+  
+  fill(255);
+  textSize(16);
+  text("Frame rate: " + int(frameRate), 10, 20);
+  
+}
+
+

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Graphics/Patch/Patch.pde

@@ -0,0 +1,161 @@
+// Bezier patch By Maritus Watz:
+// http://www.openprocessing.org/sketch/57709
+// Normal calculation added by Andres Colubri
+// Direct port of sample code by Paul Bourke.
+// Original code: http://paulbourke.net/geometry/bezier/
+
+int ni=4, nj=5, RESI=ni*10, RESJ=nj*10;
+PVector outp[][], inp[][];
+PVector normp[][]; 
+boolean autoNormals = false; 
+ 
+void setup() {
+  size(1024, 768, P3D);
+  build();
+}
+ 
+void draw() {
+  background(255);
+  translate(width/2,height/2);
+  lights();
+  scale(0.9);
+  rotateY(map(mouseX,0,width,-PI,PI));
+  rotateX(map(mouseY,0,height,-PI,PI));
+   
+  noStroke();
+  fill(255);
+  for(int i=0; i<RESI-1; i++) {
+    beginShape(QUAD_STRIP);
+    for(int j=0; j<RESJ; j++) {
+      if (!autoNormals) {
+        normal(normp[i][j].x, normp[i][j].y, normp[i][j].z);
+      }
+      vertex(outp[i][j].x,outp[i][j].y,outp[i][j].z);
+      vertex(outp[i+1][j].x,outp[i+1][j].y,outp[i+1][j].z);     
+    }
+    endShape();
+  }
+}
+ 
+void keyPressed() {
+  if(key==' ') build();
+  saveFrame("bezPatch.png");
+}
+ 
+void build() {
+  int i, j, ki, kj;
+  double mui, muj, bi, bj, dbi, dbj;
+  
+  outp=new PVector[RESI][RESJ];
+  normp=new PVector[RESI][RESJ];
+  inp=new PVector[ni+1][nj+1];
+  PVector uitang = new PVector();
+  PVector ujtang = new PVector();
+  
+  for (i=0;i<=ni;i++) {
+    for (j=0;j<=nj;j++) {
+      inp[i][j]=new PVector(i,j,random(-3,3));
+    }
+  }
+  
+  for (i=0;i<RESI;i++) {
+    mui = i / (double)(RESI-1);
+    for (j=0;j<RESJ;j++) {
+      muj = j / (double)(RESJ-1);
+      outp[i][j]=new PVector();
+      uitang.set(0, 0, 0);
+      ujtang.set(0, 0, 0);
+      for (ki=0;ki<=ni;ki++) {
+        bi = BezierBlend(ki, mui, ni);
+        dbi = DBezierBlend(ki, mui, ni);
+        for (kj=0;kj<=nj;kj++) {
+          bj = BezierBlend(kj, muj, nj);
+          dbj = DBezierBlend(kj, muj, nj);
+          outp[i][j].x += (inp[ki][kj].x * bi * bj);
+          outp[i][j].y += (inp[ki][kj].y * bi * bj);
+          outp[i][j].z += (inp[ki][kj].z * bi * bj);
+           
+          uitang.x += (inp[ki][kj].x * dbi * bj);
+          uitang.y += (inp[ki][kj].y * dbi * bj);
+          uitang.z += (inp[ki][kj].z * dbi * bj);
+           
+          ujtang.x += (inp[ki][kj].x * bi * dbj);
+          ujtang.y += (inp[ki][kj].y * bi * dbj);
+          ujtang.z += (inp[ki][kj].z * bi * dbj);
+        }
+      }
+      outp[i][j].add(new PVector(-ni/2,-nj/2,0));
+      outp[i][j].mult(100);
+       
+      uitang.normalize();
+      ujtang.normalize();
+      normp[i][j] = uitang.cross(ujtang);     
+    }
+  }
+}
+ 
+double BezierBlend(int k, double mu, int n) {
+  int nn, kn, nkn;
+  double blend=1;
+ 
+  nn = n;
+  kn = k;
+  nkn = n - k;
+ 
+  while (nn >= 1) {
+    blend *= nn;
+    nn--;
+    if (kn > 1) {
+      blend /= (double)kn;
+      kn--;
+    }
+    if (nkn > 1) {
+      blend /= (double)nkn;
+      nkn--;
+    }
+  }
+  if (k > 0)
+    blend *= Math.pow(mu, (double)k);
+  if (n-k > 0)
+    blend *= Math.pow(1-mu, (double)(n-k));
+ 
+  return(blend);
+}
+
+double DBezierBlend(int k, double mu, int n) {
+  int nn, kn, nkn;
+  double dblendf = 1;
+  
+  nn = n;
+  kn = k;
+  nkn = n - k;
+  
+  while (nn >= 1) {
+    dblendf *= nn;
+    nn--;
+    if (kn > 1) {
+      dblendf /= (double)kn;
+      kn--;
+    }
+    if (nkn > 1) {
+      dblendf /= (double)nkn;
+      nkn--;
+    }
+  }
+   
+  double fk = 1;
+  double dk = 0;
+  double fnk = 1;
+  double dnk = 0;   
+  if (k > 0) {
+    fk = Math.pow(mu, (double)k);
+    dk = k*Math.pow(mu, (double)k-1);
+  } 
+  if (n-k > 0) {
+    fnk = Math.pow(1-mu, (double)(n-k));
+    dnk = (k-n)*Math.pow(1-mu, (double)(n-k-1));
+  }
+  dblendf *= (dk * fnk + fk * dnk);
+  
+  return(dblendf); 
+}

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Graphics/Planets/Perlin.pde

@@ -0,0 +1,261 @@
+// Implementation of 1D, 2D, and 3D Perlin noise. Based on the 
+// C code by Paul Bourke:
+// http://local.wasp.uwa.edu.au/~pbourke/texture_colour/perlin/
+class Perlin {
+  int B = 0x100;
+  int BM = 0xff;
+  int N = 0x1000;
+  int NP = 12; 
+  int NM = 0xfff;
+
+  int p[];
+  float g3[][];
+  float g2[][];
+  float g1[];
+
+  void normalize2(float v[]) {
+    float s = sqrt(v[0] * v[0] + v[1] * v[1]);
+    v[0] = v[0] / s;
+    v[1] = v[1] / s;
+  }
+
+  void normalize3(float v[]) {
+    float s = sqrt(v[0] * v[0] + v[1] * v[1] + v[2] * v[2]);
+    v[0] = v[0] / s;
+    v[1] = v[1] / s;
+    v[2] = v[2] / s;
+  }
+
+  float sCurve(float t) {
+    return t * t * (3.0 - 2.0 * t);
+  }
+
+  float at2(float q[], float rx, float ry) { 
+    return rx * q[0] + ry * q[1];
+  }
+
+  float at3(float q[], float rx, float ry, float rz) { 
+    return rx * q[0] + ry * q[1] + rz * q[2];
+  }
+
+  Perlin() {
+    p = new int[B + B + 2];
+    g3 = new float[B + B + 2][3];
+    g2 = new float[B + B + 2][2];
+    g1 = new float[B + B + 2];  
+
+    init();
+  }  
+
+  void init() {
+    int i, j, k;
+
+    for (i = 0 ; i < B ; i++) {
+      p[i] = i;
+      g1[i] = (random(B + B) - B) / B;
+
+      for (j = 0 ; j < 2 ; j++)
+        g2[i][j] = (random(B + B) - B) / B;
+      normalize2(g2[i]);
+
+      for (j = 0 ; j < 3 ; j++)
+        g3[i][j] = (random(B + B) - B) / B;
+      normalize3(g3[i]);
+    }
+
+    while (0 < --i) {
+      k = p[i];
+      p[i] = p[j = int(random(B))];
+      p[j] = k;
+    }
+
+    for (i = 0 ; i < B + 2 ; i++) {
+      p[B + i] = p[i];
+      g1[B + i] = g1[i];
+      for (j = 0 ; j < 2 ; j++)
+        g2[B + i][j] = g2[i][j];
+      for (j = 0 ; j < 3 ; j++)
+        g3[B + i][j] = g3[i][j];
+    }
+  }
+
+  float noise1(float[] vec) {
+    int bx0, bx1;
+    float rx0, rx1, sx, t, u, v;
+
+    t = vec[0] + N;
+    bx0 = int(t) & BM;
+    bx1 = (bx0 + 1) & BM;
+    rx0 = t - int(t);
+    rx1 = rx0 - 1.0; 
+
+    sx = sCurve(rx0);
+    u = rx0 * g1[p[bx0]];
+    v = rx1 * g1[p[bx1]];
+
+    return lerp(u, v, sx);
+  }
+
+  float noise2(float[] vec) {
+    int bx0, bx1, by0, by1, b00, b10, b01, b11;
+    float rx0, rx1, ry0, ry1, sx, sy, a, b, t, u, v;
+    float[] q;    
+    int i, j;
+
+    t = vec[0] + N;
+    bx0 = int(t) & BM;
+    bx1 = (bx0 + 1) & BM;
+    rx0 = t - int(t);
+    rx1 = rx0 - 1.0; 
+
+    t = vec[1] + N;
+    by0 = int(t) & BM;
+    by1 = (by0 + 1) & BM;
+    ry0 = t - int(t);
+    ry1 = ry0 - 1.0;
+
+    i = p[bx0];
+    j = p[bx1];
+
+    b00 = p[i + by0];
+    b10 = p[j + by0];
+    b01 = p[i + by1];
+    b11 = p[j + by1];
+
+    sx = sCurve(rx0);
+    sy = sCurve(ry0);
+
+    q = g2[b00]; 
+    u = at2(q, rx0, ry0);
+    q = g2[b10]; 
+    v = at2(q, rx1, ry0);
+    a = lerp(u, v, sx);
+
+    q = g2[b01] ; 
+    u = at2(q, rx0, ry1);
+    q = g2[b11] ; 
+    v = at2(q, rx1, ry1);
+    b = lerp(u, v, sx);
+
+    return lerp(a, b, sy);
+  }
+
+  float noise3(float[] vec) {
+    int bx0, bx1, by0, by1, bz0, bz1, b00, b10, b01, b11;
+    float rx0, rx1, ry0, ry1, rz0, rz1, sy, sz, a, b, c, d, t, u, v;
+    float[] q;
+    int i, j;
+
+    t = vec[0] + N;
+    bx0 = int(t) & BM;
+    bx1 = (bx0 + 1) & BM;
+    rx0 = t - int(t);
+    rx1 = rx0 - 1.0;
+
+    t = vec[1] + N;
+    by0 = int(t) & BM;
+    by1 = (by0 + 1) & BM;
+    ry0 = t - int(t);
+    ry1 = ry0 - 1.0;
+
+    t = vec[2] + N;
+    bz0 = int(t) & BM;
+    bz1 = (bz0 + 1) & BM;
+    rz0 = t - int(t);
+    rz1 = rz0 - 1.0;
+
+    i = p[bx0];
+    j = p[bx1];
+
+    b00 = p[i + by0];
+    b10 = p[j + by0];
+    b01 = p[i + by1];
+    b11 = p[j + by1];
+
+    t  = sCurve(rx0);
+    sy = sCurve(ry0);
+    sz = sCurve(rz0);
+
+    q = g3[b00 + bz0]; 
+    u = at3(q, rx0, ry0, rz0);
+    q = g3[b10 + bz0]; 
+    v = at3(q, rx1, ry0, rz0);
+    a = lerp(u, v, t);
+
+    q = g3[b01 + bz0]; 
+    u = at3(q, rx0, ry1, rz0);
+    q = g3[b11 + bz0]; 
+    v = at3(q, rx1, ry1, rz0);
+    b = lerp(u, v, t);
+
+    c = lerp(a, b, sy);
+
+    q = g3[b00 + bz1]; 
+    u = at3(q, rx0, ry0, rz1);
+    q = g3[b10 + bz1]; 
+    v = at3(q, rx1, ry0, rz1);
+    a = lerp(u, v, t);
+
+    q = g3[b01 + bz1]; 
+    u = at3(q, rx0, ry1, rz1);
+    q = g3[b11 + bz1]; 
+    v = at3(q, rx1, ry1, rz1);
+    b = lerp(u, v, t);
+
+    d = lerp(a, b, sy);
+
+    return lerp(c, d, sz);
+  }
+
+  // In what follows "nalpha" is the weight when the sum is formed.
+  // Typically it is 2, as this approaches 1 the function is noisier.
+  // "nbeta" is the harmonic scaling/spacing, typically 2. n is the
+  // number of harmonics added up in the final result. Higher number 
+  // results in more detailed noise.
+
+  float noise1D(float x, float nalpha, float nbeta, int n) {
+    float val, sum = 0;
+    float v[] = {x};
+    float nscale = 1;
+
+    for (int i = 0; i < n; i++) {
+      val = noise1(v);
+      sum += val / nscale;
+      nscale *= nalpha;
+      v[0] *= nbeta;
+    }
+    return sum;
+  }
+
+  float noise2D(float x, float y, float nalpha, float nbeta, int n) {
+   float val,sum = 0;
+   float v[] = {x, y};
+   float nscale = 1;
+
+   for (int i = 0; i < n; i++) {
+      val = noise2(v);
+      sum += val / nscale;
+      nscale *= nalpha;
+      v[0] *= nbeta;
+      v[1] *= nbeta;
+   }
+   return sum;
+  }
+
+  float noise3D(float x, float y, float z, float nalpha, float nbeta, int n) {
+    float val, sum = 0;
+    float v[] = {x, y, z};
+    float nscale = 1;
+
+    for (int i = 0 ; i < n; i++) {
+      val = noise3(v);
+      sum += val / nscale;
+      nscale *= nalpha;
+      v[0] *= nbeta;
+      v[1] *= nbeta;
+      v[2] *= nbeta;
+    }
+    return sum;
+  }
+}
+

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Graphics/Planets/Planets.pde

@@ -0,0 +1,109 @@
+// Planets, by Andres Colubri
+//
+// Sun and mercury textures from http://planetpixelemporium.com
+// Star field picture from http://www.galacticimages.com/
+
+PImage starfield;
+
+PShape sun;
+PImage suntex;
+
+PShape planet1;
+PImage surftex1;
+PImage cloudtex;
+
+PShape planet2;
+PImage surftex2;
+
+void setup() {
+  size(1024, 768, P3D);
+  
+  starfield = loadImage("starfield.jpg");
+  suntex = loadImage("sun.jpg");  
+  surftex1 = loadImage("planet.jpg");  
+   
+  // We need trilinear sampling for this texture so it looks good
+  // even when rendered very small.
+  //PTexture.Parameters params1 = PTexture.newParameters(ARGB, TRILINEAR);  
+  surftex2 = loadImage("mercury.jpg");  
+  
+  /*
+  // The clouds texture will "move" having the values of its u
+  // texture coordinates displaced by adding a constant increment
+  // in each frame. This requires REPEAT wrapping mode so texture 
+  // coordinates can be larger than 1.
+  //PTexture.Parameters params2 = PTexture.newParameters();
+  //params2.wrapU = REPEAT;
+  cloudtex = createImage(512, 256);
+
+  // Using 3D Perlin noise to generate a clouds texture that is seamless on
+  // its edges so it can be applied on a sphere.
+  cloudtex.loadPixels();
+  Perlin perlin = new Perlin();
+  for (int j = 0; j < cloudtex.height; j++) {
+    for (int i = 0; i < cloudtex.width; i++) {
+      // The angle values corresponding to each u,v pair:
+      float u = float(i) / cloudtex.width;
+      float v = float(j) / cloudtex.height;
+      float phi = map(u, 0, 1, TWO_PI, 0); 
+      float theta = map(v, 0, 1, -HALF_PI, HALF_PI);
+      // The x, y, z point corresponding to these angles:
+      float x = cos(phi) * cos(theta);
+      float y = sin(theta);            
+      float z = sin(phi) * cos(theta);      
+      float n = perlin.noise3D(x, y, z, 1.2, 2, 8);
+      cloudtex.pixels[j * cloudtex.width + i] = color(255, 255,  255, 255 * n * n);
+    }
+  }  
+  cloudtex.updatePixels();
+  */
+
+  noStroke();
+  fill(255);
+  sphereDetail(40);
+
+  sun = createShape(SPHERE, 150);
+  sun.setTexture(suntex);  
+
+  planet1 = createShape(SPHERE, 150);
+  planet1.setTexture(surftex1);
+  
+  planet2 = createShape(SPHERE, 50);
+  planet2.setTexture(surftex2);
+}
+
+void draw() {
+  // Even we draw a full screen image after this, it is recommended to use
+  // background to clear the screen anyways, otherwise A3D will think
+  // you want to keep each drawn frame in the framebuffer, which results in 
+  // slower rendering.
+  background(0);
+  
+  // Disabling writing to the depth mask so the 
+  // background image doesn't occludes any 3D object.
+  hint(DISABLE_DEPTH_MASK);
+  image(starfield, 0, 0, width, height);
+  hint(ENABLE_DEPTH_MASK);
+  
+  pushMatrix();
+  translate(width/2, height/2, -300);  
+  
+  pushMatrix();
+  rotateY(PI * frameCount / 500);
+  shape(sun);
+  popMatrix();
+
+  pointLight(255,  255,  255,  0,  0,  0);  
+  rotateY(PI * frameCount / 300);
+  translate(0, 0, 300);
+
+  shape(planet2);  
+  
+  popMatrix();
+  
+  noLights();
+  pointLight(255,  255,  255,  0,  0,  -150); 
+  
+  translate(0.75 * width,  0.6 * height,  50);
+  shape(planet1);
+}

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Graphics/Ribbons/ArcBall.pde

@@ -0,0 +1,190 @@
+// Ariel and V3ga's arcball class with a couple tiny mods by Robert Hodgin
+
+class Arcball {
+  float center_x, center_y, radius;
+  Vec3 v_down, v_drag;
+  Quat q_now, q_down, q_drag;
+  Vec3[] axisSet;
+  int axis;
+  float mxv, myv;
+  float x, y;
+  
+  Arcball(float center_x, float center_y, float radius){
+    this.center_x = center_x;
+    this.center_y = center_y;
+    this.radius = radius;
+
+    v_down = new Vec3();
+    v_drag = new Vec3();
+
+    q_now = new Quat();
+    q_down = new Quat();
+    q_drag = new Quat();
+
+    axisSet = new Vec3[] {new Vec3(1.0f, 0.0f, 0.0f), new Vec3(0.0f, 1.0f, 0.0f), new Vec3(0.0f, 0.0f, 1.0f)};
+    axis = -1;  // no constraints...    
+  }
+
+  void mousePressed(){
+    v_down = mouse_to_sphere(mouseX, mouseY);
+    q_down.set(q_now);
+    q_drag.reset();
+  }
+
+  void mouseDragged(){
+    v_drag = mouse_to_sphere(mouseX, mouseY);
+    q_drag.set(Vec3.dot(v_down, v_drag), Vec3.cross(v_down, v_drag));
+  }
+
+  void run(){
+    q_now = Quat.mul(q_drag, q_down);
+    applyQuat2Matrix(q_now);
+    
+    x += mxv;
+    y += myv;
+    mxv -= mxv * .01;
+    myv -= myv * .01;
+  }
+  
+  Vec3 mouse_to_sphere(float x, float y){
+    Vec3 v = new Vec3();
+    v.x = (x - center_x) / radius;
+    v.y = (y - center_y) / radius;
+
+    float mag = v.x * v.x + v.y * v.y;
+    if (mag > 1.0f){
+      v.normalize();
+    } else {
+      v.z = sqrt(1.0f - mag);
+    }
+
+    return (axis == -1) ? v : constrain_vector(v, axisSet[axis]);
+  }
+
+  Vec3 constrain_vector(Vec3 vector, Vec3 axis){
+    Vec3 res = new Vec3();
+    res.sub(vector, Vec3.mul(axis, Vec3.dot(axis, vector)));
+    res.normalize();
+    return res;
+  }
+
+  void applyQuat2Matrix(Quat q){
+    // instead of transforming q into a matrix and applying it...
+
+    float[] aa = q.getValue();
+    rotate(aa[0], aa[1], aa[2], aa[3]);
+  }
+}
+
+static class Vec3{
+  float x, y, z;
+
+  Vec3(){
+  }
+
+  Vec3(float x, float y, float z){
+    this.x = x;
+    this.y = y;
+    this.z = z;
+  }
+
+  void normalize(){
+    float length = length();
+    x /= length;
+    y /= length;
+    z /= length;
+  }
+
+  float length(){
+    return (float) Math.sqrt(x * x + y * y + z * z);
+  }
+
+  static Vec3 cross(Vec3 v1, Vec3 v2){
+    Vec3 res = new Vec3();
+    res.x = v1.y * v2.z - v1.z * v2.y;
+    res.y = v1.z * v2.x - v1.x * v2.z;
+    res.z = v1.x * v2.y - v1.y * v2.x;
+    return res;
+  }
+
+  static float dot(Vec3 v1, Vec3 v2){
+    return v1.x * v2.x + v1.y * v2.y + v1.z * v2.z;
+  }
+  
+  static Vec3 mul(Vec3 v, float d){
+    Vec3 res = new Vec3();
+    res.x = v.x * d;
+    res.y = v.y * d;
+    res.z = v.z * d;
+    return res;
+  }
+
+  void sub(Vec3 v1, Vec3 v2){
+    x = v1.x - v2.x;
+    y = v1.y - v2.y;
+    z = v1.z - v2.z;
+  }
+}
+
+static class Quat{
+  float w, x, y, z;
+
+  Quat(){
+    reset();
+  }
+
+  Quat(float w, float x, float y, float z){
+    this.w = w;
+    this.x = x;
+    this.y = y;
+    this.z = z;
+  }
+
+  void reset(){
+    w = 1.0f;
+    x = 0.0f;
+    y = 0.0f;
+    z = 0.0f;
+  }
+
+  void set(float w, Vec3 v){
+    this.w = w;
+    x = v.x;
+    y = v.y;
+    z = v.z;
+  }
+
+  void set(Quat q){
+    w = q.w;
+    x = q.x;
+    y = q.y;
+    z = q.z;
+  }
+
+  static Quat mul(Quat q1, Quat q2){
+    Quat res = new Quat();
+    res.w = q1.w * q2.w - q1.x * q2.x - q1.y * q2.y - q1.z * q2.z;
+    res.x = q1.w * q2.x + q1.x * q2.w + q1.y * q2.z - q1.z * q2.y;
+    res.y = q1.w * q2.y + q1.y * q2.w + q1.z * q2.x - q1.x * q2.z;
+    res.z = q1.w * q2.z + q1.z * q2.w + q1.x * q2.y - q1.y * q2.x;
+    return res;
+  }
+  
+  float[] getValue(){
+    // transforming this quat into an angle and an axis vector...
+
+    float[] res = new float[4];
+
+    float sa = (float) Math.sqrt(1.0f - w * w);
+    if (sa < EPSILON){
+      sa = 1.0f;
+    }
+
+    res[0] = (float) Math.acos(w) * 2.0f;
+    res[1] = x / sa;
+    res[2] = y / sa;
+    res[3] = z / sa;
+
+    return res;
+  }
+}

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Graphics/Ribbons/BSpline.pde

@@ -0,0 +1,307 @@
+final int MAX_BEZIER_ORDER = 10; // Maximum curve order.
+
+final float[][] BSplineMatrix = {
+  {-1.0/6.0,  1.0/2.0, -1.0/2.0, 1.0/6.0},
+  { 1.0/2.0,     -1.0,  1.0/2.0,     0.0},
+  {-1.0/2.0,      0.0,  1.0/2.0,     0.0},
+  { 1.0/6.0,  2.0/3.0,  1.0/6.0,     0.0}
+};
+
+// The element(i, n) of this array contains the binomial coefficient
+// C(i, n) = n!/(i!(n-i)!)
+final int[][] BinomialCoefTable = {
+  {1, 1, 1, 1,  1,  1,  1,  1,   1,   1},
+  {1, 2, 3, 4,  5,  6,  7,  8,   9,  10},
+  {0, 1, 3, 6, 10, 15, 21, 28,  36,  45},
+  {0, 0, 1, 4, 10, 20, 35, 56,  84, 120},
+  {0, 0, 0, 1,  5, 15, 35, 70, 126, 210},
+  {0, 0, 0, 0,  1,  6, 21, 56, 126, 252},
+  {0, 0, 0, 0,  0,  1,  7, 28,  84, 210},
+  {0, 0, 0, 0,  0,  0,  1,  8,  36, 120},
+  {0, 0, 0, 0,  0,  0,  0,  1,   9,  45},
+  {0, 0, 0, 0,  0,  0,  0,  0,   1,  10},
+  {0, 0, 0, 0,  0,  0,  0,  0,   0,   1}
+};
+
+// The element of this(i, j) of this table contains(i/10)^(3-j).
+final float[][] TVectorTable = {  
+//   t^3,  t^2, t^1, t^0
+  {    0,    0,   0,   1}, // t = 0.0
+  {0.001, 0.01, 0.1,   1}, // t = 0.1
+  {0.008, 0.04, 0.2,   1}, // t = 0.2
+  {0.027, 0.09, 0.3,   1}, // t = 0.3
+  {0.064, 0.16, 0.4,   1}, // t = 0.4
+  {0.125, 0.25, 0.5,   1}, // t = 0.5
+  {0.216, 0.36, 0.6,   1}, // t = 0.6
+  {0.343, 0.49, 0.7,   1}, // t = 0.7
+  {0.512, 0.64, 0.8,   1}, // u = 0.8
+  {0.729, 0.81, 0.9,   1}, // t = 0.9
+  {    1,    1,   1,   1}  // t = 1.0
+};
+
+// The element of this(i, j) of this table contains(3-j)*(i/10)^(2-j) if
+// j < 3, 0 otherwise.
+final float[][] DTVectorTable = { 
+// 3t^2,  2t^1, t^0
+  {   0,     0,   1, 0}, // t = 0.0
+  {0.03,   0.2,   1, 0}, // t = 0.1
+  {0.12,   0.4,   1, 0}, // t = 0.2
+  {0.27,   0.6,   1, 0}, // t = 0.3
+  {0.48,   0.8,   1, 0}, // t = 0.4
+  {0.75,   1.0,   1, 0}, // t = 0.5
+  {1.08,   1.2,   1, 0}, // t = 0.6
+  {1.47,   1.4,   1, 0}, // t = 0.7
+  {1.92,   1.6,   1, 0}, // t = 0.8
+  {2.43,   1.8,   1, 0}, // t = 0.9
+  {   3,     2,   1, 0}  // t = 1.0
+};
+
+abstract class Curve3D {
+  abstract void feval(float t, PVector p);
+  abstract void deval(float t, PVector d);
+  abstract float fevalX(float t);
+  abstract float fevalY(float t);
+  abstract float fevalZ(float t);
+  abstract float devalX(float t);
+  abstract float devalY(float t);
+  abstract float devalZ(float t);
+}
+
+abstract class Spline extends Curve3D {
+  // The factorial of n.
+  int factorial(int n) { 
+    return n <= 0 ? 1 : n * factorial(n - 1); 
+  }
+  
+  // Gives n!/(i!(n-i)!).
+  int binomialCoef(int i, int n) {
+    if ((i <= MAX_BEZIER_ORDER) && (n <= MAX_BEZIER_ORDER)) return BinomialCoefTable[i][n - 1];
+    else return int(factorial(n) / (factorial(i) * factorial(n - i)));
+  }
+  
+  // Evaluates the Berstein polinomial(i, n) at u.
+  float bersteinPol(int i, int n, float u) {
+    return binomialCoef(i, n) * pow(u, i) * pow(1 - u, n - i);
+  }
+  
+  // The derivative of the Berstein polinomial.
+  float dbersteinPol(int i, int n, float u) {
+    float s1, s2; 
+    if (i == 0) s1 = 0; 
+    else s1 = i * pow(u, i-1) * pow(1 - u, n - i);
+    if (n == i) s2 = 0; 
+    else s2 = -(n - i) * pow(u, i) * pow(1 - u, n - i - 1);
+    return binomialCoef(i, n) *(s1 + s2);
+  }
+}
+
+class BSpline extends Spline {
+  // Control points.
+  float[][] bsplineCPoints;
+
+  // Parameters.
+  boolean lookup;
+
+  // Auxiliary arrays used in the calculations.
+  float[][] M3;
+  float[] TVector, DTVector;
+
+  // Point and tangent vectors.
+  float[] pt, tg;
+  
+  BSpline() { 
+    initParameters(true); 
+  }
+  
+  BSpline(boolean t) { 
+    initParameters(t); 
+  }
+
+  // Sets lookup table use.
+  void initParameters(boolean t) { 
+    bsplineCPoints = new float[4][3];
+    TVector = new float[4];
+    DTVector = new float[4]; 
+    M3 = new float[4][3];
+    pt = new float[3];
+    tg = new float[3];        
+    lookup = t;
+  }
+  
+  // Sets n-th control point.
+  void setCPoint(int n, PVector P) {
+    bsplineCPoints[n][0] = P.x;
+    bsplineCPoints[n][1] = P.y;
+    bsplineCPoints[n][2] = P.z;        
+    updateMatrix3();
+  }
+
+  // Gets n-th control point.
+  void getCPoint(int n, PVector P) {
+    P.set(bsplineCPoints[n]);
+  }
+
+  // Replaces the current B-spline control points(0, 1, 2) with(1, 2, 3). This
+  // is used when a new spline is to be joined to the recently drawn.
+  void shiftBSplineCPoints() {
+    for (int i = 0; i < 3; i++) {
+      bsplineCPoints[0][i] = bsplineCPoints[1][i];
+      bsplineCPoints[1][i] = bsplineCPoints[2][i];
+      bsplineCPoints[2][i] = bsplineCPoints[3][i];
+    }
+    updateMatrix3();
+  }
+
+  void copyCPoints(int n_source, int n_dest) {
+    for (int i = 0; i < 3; i++) {
+      bsplineCPoints[n_dest][i] = bsplineCPoints[n_source][i];
+    }
+  }
+
+  // Updates the temporal matrix used in order 3 calculations.
+  void updateMatrix3() {
+    float s; 
+    int i, j, k;
+    for(i = 0; i < 4; i++) {
+      for(j = 0; j < 3; j++) {
+        s = 0;
+        for(k = 0; k < 4; k++) s += BSplineMatrix[i][k] * bsplineCPoints[k][j];
+        M3[i][j] = s;
+      }
+    }
+  }    
+
+  void feval(float t, PVector p) { 
+    evalPoint(t); 
+    p.set(pt); 
+  }
+  
+  void deval(float t, PVector d) { 
+    evalTangent(t); 
+    d.set(tg); 
+  }
+
+  float fevalX(float t) { 
+    evalPoint(t); 
+    return pt[0]; 
+  }
+  
+  float fevalY(float t) { 
+    evalPoint(t); 
+    return pt[1]; 
+  }
+  
+  float fevalZ(float t) { 
+    evalPoint(t); 
+    return pt[2]; 
+  }
+
+  float devalX(float t) { 
+    evalTangent(t); 
+    return tg[0]; 
+  }
+  
+  float devalY(float t) { 
+    evalTangent(t); 
+    return tg[1]; 
+  }
+  
+  float devalZ(float t) { 
+    evalTangent(t); 
+    return tg[2]; 
+  }
+
+  // Point evaluation.
+  void evalPoint(float t) {
+    if (lookup) {
+      bsplinePointI(int(10 * t));
+    } else {
+      bsplinePoint(t);
+    }
+  }    
+
+  // Tangent evaluation.
+  void evalTangent(float t) {
+    if (lookup) {
+      bsplineTangentI(int(10 * t));
+    } else {
+      bsplineTangent(t);
+    }
+  }    
+
+  // Calculates the point on the cubic spline corresponding to the parameter value t in [0, 1].
+  void bsplinePoint(float t) {
+    // Q(u) = UVector * BSplineMatrix * BSplineCPoints
+
+    float s;
+    int i, j, k;
+
+    for(i = 0; i < 4; i++) {
+      TVector[i] = pow(t, 3 - i);
+    }
+
+    for(j = 0; j < 3; j++) {
+      s = 0;
+      for(k = 0; k < 4; k++) {
+        s += TVector[k] * M3[k][j];
+      }
+      pt[j] = s;
+    }
+  }
+
+  // Calculates the tangent vector of the spline at t.
+  void bsplineTangent(float t) {
+    // Q(u) = DTVector * BSplineMatrix * BSplineCPoints
+
+    float s;
+    int i, j, k;
+
+    for(i = 0; i < 4; i++) {
+      if (i < 3) {
+        DTVector[i] = (3 - i) * pow(t, 2 - i);
+      } else {
+        DTVector[i] = 0;
+      }
+    }
+
+    for(j = 0; j < 3; j++) {
+      s = 0;
+      for(k = 0; k < 4; k++) {
+        s += DTVector[k] * M3[k][j];
+      }
+      tg[j] = s;
+    }
+  }
+
+  // Gives the point on the cubic spline corresponding to t/10(using the lookup table).
+  void bsplinePointI(int t) {
+    // Q(u) = TVectorTable[u] * BSplineMatrix * BSplineCPoints
+
+    float s;
+    int j, k;
+
+    for(j = 0; j < 3; j++) {
+      s = 0;
+      for(k = 0; k < 4; k++) {
+        s += TVectorTable[t][k] * M3[k][j];
+      }
+      pt[j] = s;
+    }
+  }
+
+  // Calulates the tangent vector of the spline at t/10.
+  void bsplineTangentI(int t) {
+    // Q(u) = DTVectorTable[u] * BSplineMatrix * BSplineCPoints
+
+    float s;
+    int j, k;
+
+    for(j = 0; j < 3; j++) {
+      s = 0;
+      for(k = 0; k < 4; k++) {
+        s += DTVectorTable[t][k] * M3[k][j];
+      }
+      tg[j] = s;
+    }
+  }    
+}

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Graphics/Ribbons/Geometry.pde

@@ -0,0 +1,497 @@
+BSpline splineSide1;
+BSpline splineCenter;
+BSpline splineSide2;
+PVector flipTestV;
+int uspacing;
+
+int HELIX = 0;
+int STRAND = 1;
+int COIL = 2;
+int LHANDED = -1;
+int RHANDED = 1;
+
+void createRibbonModel(ArrayList residues, PShape model, ArrayList trj) {
+  // For line ribbons
+  ArrayList vertices0 = new ArrayList();
+  ArrayList vertices1 = new ArrayList();
+  ArrayList vertices2 = new ArrayList();
+  
+  // For flat ribbons
+  ArrayList vertices = new ArrayList();
+  ArrayList normals = new ArrayList();
+    
+  if (ribbonDetail == 1) uspacing = 10;
+  else if (ribbonDetail == 2) uspacing = 5;
+  else if (ribbonDetail == 3) uspacing = 2;
+  else uspacing = 1;
+
+  flipTestV = new PVector();
+  splineSide1 = new BSpline(false);
+  splineCenter = new BSpline(false);
+  splineSide2 = new BSpline(false);
+
+  int[] ss = new int[residues.size()];
+  int[] handness = new int[residues.size()];
+
+  calculateSecStr(residues, ss, handness);   
+
+  for (int i = 0; i < residues.size(); i++) {
+    constructControlPoints(residues, i, ss[i], handness[i]);
+
+    if (renderMode == 0) {
+      generateSpline(0, vertices0);
+      generateSpline(1, vertices1);        
+      generateSpline(2, vertices2);        
+    } 
+    else {
+      generateFlatRibbon(vertices, normals);
+    }
+  }  
+
+  if (renderMode == 0) {
+    model = createShape();
+    model.beginShape();
+    model.stroke(ribbonColor);
+    model.noFill();    
+    model.beginContour();
+    for (int i = 0; i < vertices0.size(); i++) {
+      PVector posVec = (PVector)vertices0.get(i);
+      model.vertex(posVec.x, posVec.y, posVec.z);    
+    }
+    model.endContour();
+    model.beginContour();
+    for (int i = 0; i < vertices1.size(); i++) {
+      PVector posVec = (PVector)vertices1.get(i);
+      model.vertex(posVec.x, posVec.y, posVec.z);    
+    }
+    model.endContour();    
+    model.beginContour();
+    for (int i = 0; i < vertices2.size(); i++) {
+      PVector posVec = (PVector)vertices2.get(i);
+      model.vertex(posVec.x, posVec.y, posVec.z);    
+    }
+    model.endContour();    
+    model.endShape(OPEN);    
+  } else {
+    // The ribbon construction is fairly inneficient here, since
+    // it could use triangle strips instead to avoid duplicating
+    // shared vertices...
+    model = createShape();
+    model.beginShape(TRIANGLES);
+    model.noStroke();
+    model.fill(ribbonColor);
+    for (int i = 0; i < vertices.size(); i++) {
+      PVector posVec = (PVector)vertices.get(i);
+      PVector normVec = (PVector)normals.get(i);
+      model.normal(-normVec.x, -normVec.y, -normVec.z);
+      model.vertex(posVec.x, posVec.y, posVec.z);
+    }
+    model.endShape();
+  }
+  
+  trj.add(model);
+
+  if (renderMode == 0) {
+    int totCount = vertices0.size() + vertices1.size() + vertices2.size();
+    println("Adding new model with " + totCount + " vertices.");
+  } else {
+    println("Adding new model with " + vertices.size() + " vertices.");
+  }
+}
+
+float calculateGyrRadius(ArrayList atoms) {
+  PVector ati, atj;
+  float dx, dy, dz;    
+  float r = 0;
+  for (int i = 0; i < atoms.size(); i++) {
+    ati = (PVector)atoms.get(i);
+    for (int j = i + 1; j < atoms.size(); j++) {  
+      atj = (PVector)atoms.get(j);
+
+      dx = ati.x - atj.x;
+      dy = ati.y - atj.y;
+      dz = ati.z - atj.z;
+      r +=  dx * dx + dy * dy + dz * dz;
+    }
+  }
+  return sqrt(r) / (atoms.size() + 1);
+}
+
+// Does a cheap and dirty secondary structure assignment to the protein
+// residues given in the array.
+void calculateSecStr(ArrayList residues, int[] ss, int[] handness) {
+  PVector c0, n1, ca1, c1, n2;
+  HashMap res0, res1, res2;
+  int n = residues.size();
+
+  float[] phi = new float[n];
+  float[] psi = new float[n];
+
+  for (int i = 0; i < n; i++) {
+    if (i == 0 || i == n - 1) {
+      phi[i] = 90;
+      psi[i] = 90;              
+    } else {
+      res0 = (HashMap)residues.get(i - 1);
+      res1 = (HashMap)residues.get(i);
+      res2 = (HashMap)residues.get(i + 1);
+
+      c0 = (PVector)res0.get("C");
+      n1 = (PVector)res1.get("N");
+      ca1 = (PVector)res1.get("CA"); 
+      c1 = (PVector)res1.get("C");
+      n2 = (PVector)res2.get("N");
+
+      phi[i] = calculateTorsionalAngle(c0, n1, ca1, c1);
+      psi[i] = calculateTorsionalAngle(n1, ca1, c1, n2);
+    }
+  }  
+
+  int firstHelix = 0;
+  int nconsRHelix = 0;
+  int nconsLHelix = 0;
+  int firstStrand = 0;
+  int nconsStrand = 0;
+  for (int i = 0; i < n; i++) {
+    // Right-handed helix      
+    if ((dist(phi[i], psi[i], -60, -45) < 30) && (i < n - 1)) {
+      if (nconsRHelix == 0) firstHelix = i;
+      nconsRHelix++;
+    } 
+    else {
+      if (3 <= nconsRHelix) {
+        for (int k = firstHelix; k < i; k++) {
+          ss[k] = HELIX;
+          handness[k] = RHANDED;                  
+        }
+      }
+      nconsRHelix = 0;
+    }
+
+    // Left-handed helix
+    if ((dist(phi[i], psi[i], +60, +45) < 30) && (i < n - 1)) {
+      if (nconsLHelix == 0) firstHelix = i;
+      nconsLHelix++;
+
+    } else {
+      if (3 <= nconsLHelix) {
+        for (int k = firstHelix; k < i; k++) {
+          ss[k] = HELIX;
+          handness[k] = LHANDED;
+        }
+      }
+      nconsLHelix = 0;
+    }
+
+    // Strand
+    if ((dist(phi[i], psi[i], -110, +130) < 30) && (i < n - 1)) {
+      if (nconsStrand == 0) firstStrand = i;
+      nconsStrand++;
+    } else {
+      if (2 <= nconsStrand) {
+        for (int k = firstStrand; k < i; k++) {
+          ss[k] = STRAND;
+          handness[k] = RHANDED;
+
+        }
+      }
+      nconsStrand = 0;
+    }        
+
+    ss[i] = COIL;
+    handness[i] = RHANDED;
+  }
+}
+
+// Calculates the torsional angle defined by four atoms with positions at0, at1, at2 and at3.
+float calculateTorsionalAngle(PVector at0, PVector at1, PVector at2, PVector at3) {
+  PVector r01 = PVector.sub(at0, at1);
+  PVector r32 = PVector.sub(at3, at2);
+  PVector r12 = PVector.sub(at1, at2);
+
+  PVector p = r12.cross(r01);
+  PVector q = r12.cross(r32);
+  PVector r = r12.cross(q);
+
+  float u = q.dot(q);
+  float v = r.dot(r);    
+
+  float a;
+  if (u <= 0.0 || v <= 0.0) {
+    a = 360.0;
+  } else {
+    float u1 = p.dot(q); // u1 = p * q
+    float v1 = p.dot(r); // v1 = p * r
+
+      u = u1 / sqrt(u);
+    v = v1 / sqrt(v);
+
+    if (abs(u) > 0.01 || abs(v) > 0.01) a = degrees(atan2(v, u));
+    else a = 360.0;
+  }    
+  return a;
+}
+
+void generateSpline(int n, ArrayList vertices) {
+  int ui;
+  float u;
+  PVector v0, v1;
+
+  v1 = new PVector();
+
+  if (n == 0) splineSide1.feval(0, v1); 
+  else if (n == 1) splineCenter.feval(0, v1);
+  else splineSide2.feval(0, v1);
+  vertices.add(new PVector(v1.x, v1.y, v1.z));
+
+  for (ui = 1; ui <= 10; ui ++) {
+    if (ui % uspacing == 0) {
+      u = 0.1 * ui; 
+
+      if (n == 0) splineSide1.feval(u, v1); 
+      else if (n == 1) splineCenter.feval(u, v1); 
+      else splineSide2.feval(u, v1);
+
+      vertices.add(new PVector(v1.x, v1.y, v1.z));            
+    }
+  }
+}
+
+void generateFlatRibbon(ArrayList vertices, ArrayList normals) {
+  PVector CentPoint0, CentPoint1;
+  PVector Sid1Point0, Sid1Point1;
+  PVector Sid2Point0, Sid2Point1;
+  PVector Transversal, Tangent;
+  PVector Normal0, Normal1;
+  int ui;
+  float u;
+
+  CentPoint0 = new PVector();
+  CentPoint1 = new PVector();
+  Sid1Point0 = new PVector();
+  Sid1Point1 = new PVector();
+  Sid2Point0 = new PVector();
+  Sid2Point1 = new PVector();
+  Transversal = new PVector();
+  Tangent = new PVector();
+  Normal0 = new PVector();
+  Normal1 = new PVector();
+
+  // The initial geometry is generated.
+  splineSide1.feval(0, Sid1Point1);
+  splineCenter.feval(0, CentPoint1);
+  splineSide2.feval(0, Sid2Point1);
+
+  // The tangents at the three previous points are the same.
+  splineSide2.deval(0, Tangent);
+
+  // Vector transversal to the ribbon.    
+  Transversal = PVector.sub(Sid1Point1, Sid2Point1);
+
+  // The normal is calculated.
+  Normal1 = Transversal.cross(Tangent);
+  Normal1.normalize();
+
+  for (ui = 1; ui <= 10; ui ++) {
+    if (ui % uspacing == 0) {
+      u = 0.1 * ui;
+
+      // The geometry of the previous iteration is saved.
+      Sid1Point0.set(Sid1Point1);
+      CentPoint0.set(CentPoint1);
+      Sid2Point0.set(Sid2Point1);
+      Normal0.set(Normal1);
+
+      // The new geometry is generated.
+      splineSide1.feval(u, Sid1Point1);
+      splineCenter.feval(u, CentPoint1);
+      splineSide2.feval(u, Sid2Point1);
+
+      // The tangents at the three previous points are the same.
+      splineSide2.deval(u, Tangent);
+      // Vector transversal to the ribbon.
+      Transversal = PVector.sub(Sid1Point1, Sid2Point1);
+      // The normal is calculated.
+      Normal1 = Transversal.cross(Tangent);
+      Normal1.normalize();
+
+      // The (Sid1Point0, Sid1Point1, CentPoint1) triangle is added.
+      vertices.add(new PVector(CentPoint1.x, CentPoint1.y, CentPoint1.z));
+      normals.add(new PVector(Normal1.x, Normal1.y, Normal1.z));      
+
+      vertices.add(new PVector(Sid1Point1.x, Sid1Point1.y, Sid1Point1.z));
+      normals.add(new PVector(Normal1.x, Normal1.y, Normal1.z));
+
+      vertices.add(new PVector(Sid1Point0.x, Sid1Point0.y, Sid1Point0.z));
+      normals.add(new PVector(Normal0.x, Normal0.y, Normal0.z));
+
+      // The (Sid1Point0, CentPoint1, CentPoint0) triangle is added.
+      vertices.add(new PVector(CentPoint0.x, CentPoint0.y, CentPoint0.z));
+      normals.add(new PVector(Normal0.x, Normal0.y, Normal0.z));
+
+      vertices.add(new PVector(CentPoint1.x, CentPoint1.y, CentPoint1.z));
+      normals.add(new PVector(Normal1.x, Normal1.y, Normal1.z));      
+
+      vertices.add(new PVector(Sid1Point0.x, Sid1Point0.y, Sid1Point0.z));
+      normals.add(new PVector(Normal0.x, Normal0.y, Normal0.z));
+      
+      // (Sid2Point0, Sid2Point1, CentPoint1) triangle is added.
+      vertices.add(new PVector(Sid2Point0.x, Sid2Point0.y, Sid2Point0.z));
+      normals.add(new PVector(Normal0.x, Normal0.y, Normal0.z));
+
+      vertices.add(new PVector(Sid2Point1.x, Sid2Point1.y, Sid2Point1.z));
+      normals.add(new PVector(Normal1.x, Normal1.y, Normal1.z));                        
+
+      vertices.add(new PVector(CentPoint1.x, CentPoint1.y, CentPoint1.z));
+      normals.add(new PVector(Normal1.x, Normal1.y, Normal1.z));
+
+      // (Sid2Point0, CentPoint1, CentPoint0) triangle is added.
+      vertices.add(new PVector(Sid2Point0.x, Sid2Point0.y, Sid2Point0.z));
+      normals.add(new PVector(Normal0.x, Normal0.y, Normal0.z));                        
+     
+      vertices.add(new PVector(CentPoint1.x, CentPoint1.y, CentPoint1.z));
+      normals.add(new PVector(Normal1.x, Normal1.y, Normal1.z));
+
+      vertices.add(new PVector(CentPoint0.x, CentPoint0.y, CentPoint0.z));
+      normals.add(new PVector(Normal0.x, Normal0.y, Normal0.z));
+    }
+  }
+}
+
+/******************************************************************************
+ * The code in the following three functions is based in the method introduced 
+ * in this paper:
+ * "Algorithm for ribbon models of proteins."
+ * Authors: Mike Carson and Charles E. Bugg
+ * Published in: J.Mol.Graphics 4, pp. 121-122 (1986)
+ ******************************************************************************/
+
+// Shifts the control points one place to the left.
+void shiftControlPoints() {
+  splineSide1.shiftBSplineCPoints();
+  splineCenter.shiftBSplineCPoints();
+  splineSide2.shiftBSplineCPoints();
+}
+
+// Adds a new control point to the arrays CPCenter, CPRight and CPLeft
+void addControlPoints(PVector ca0, PVector ox0, PVector ca1, int ss, int handness) {
+  PVector A, B, C, D, p0, cpt0, cpt1, cpt2;
+
+  A = PVector.sub(ca1, ca0);
+  B = PVector.sub(ox0, ca0);
+
+  // Vector normal to the peptide plane (pointing outside in the case of the
+  // alpha helix).
+  C = A.cross(B);
+
+  // Vector contained in the peptide plane (perpendicular to its direction).
+  D = C.cross(A);
+
+  // Normalizing vectors.
+  C.normalize();
+  D.normalize();
+
+  // Flipping test (to avoid self crossing in the strands).
+  if ((ss != HELIX) && (90.0 < degrees(PVector.angleBetween(flipTestV, D)))) {
+    // Flip detected. The plane vector is inverted.
+    D.mult(-1.0);
+  }
+
+  // The central control point is constructed.
+  cpt0 = linearComb(0.5, ca0, 0.5, ca1);
+  splineCenter.setCPoint(3, cpt0);
+
+  if (ss == HELIX) {
+    // When residue i is contained in a helix, the control point is moved away
+    // from the helix axis, along the C direction. 
+    p0 = new PVector();
+    splineCenter.getCPoint(3, p0);
+    cpt0 = linearComb(1.0, p0, handness * helixDiam, C);
+    splineCenter.setCPoint(3, cpt0);
+  }
+
+  // The control points for the side ribbons are constructed.
+  cpt1 = linearComb(1.0, cpt0, +ribbonWidth[ss], D);
+  splineSide1.setCPoint(3, cpt1);
+
+  cpt2 = linearComb(1.0, cpt0, -ribbonWidth[ss], D);
+  splineSide2.setCPoint(3, cpt2);
+
+  // Saving the plane vector (for the flipping test in the next call).
+  flipTestV.set(D);
+}
+
+void constructControlPoints(ArrayList residues, int res, int ss, int handness) {
+  PVector ca0, ox0, ca1;
+  PVector p0, p1, p2, p3;
+
+  p1 = new PVector();        
+  p2 = new PVector();
+  p3 = new PVector();
+
+  HashMap res0, res1;
+
+  res0 = res1 = null;
+  if (res == 0) {
+    // The control points 2 and 3 are created.
+    flipTestV.set(0, 0, 0);
+
+    res0 = (HashMap)residues.get(res);
+    res1 = (HashMap)residues.get(res + 1);
+    ca0 = (PVector)res0.get("CA");
+    ox0 = (PVector)res0.get("O");
+    ca1 = (PVector)res1.get("CA");        
+    addControlPoints(ca0, ox0, ca1, ss, handness);
+    splineSide1.copyCPoints(3, 2);
+    splineCenter.copyCPoints(3, 2);
+    splineSide2.copyCPoints(3, 2);        
+
+    res0 = (HashMap)residues.get(res + 1);
+    res1 = (HashMap)residues.get(res + 2);
+    ca0 = (PVector)res0.get("CA");
+    ox0 = (PVector)res0.get("O");
+    ca1 = (PVector)res1.get("CA"); 
+    addControlPoints(ca0, ox0, ca1, ss, handness);
+
+    // We still need the two first control points.
+    // Moving backwards along the cp_center[2] - cp_center[3] direction.
+    splineCenter.getCPoint(2, p2);
+    splineCenter.getCPoint(3, p3);
+
+    p1 = linearComb(2.0, p2, -1, p3);
+    splineCenter.setCPoint(1, p1);        
+    splineSide1.setCPoint(1, linearComb(1.0, p1, +ribbonWidth[ss], flipTestV)); 
+    splineSide2.setCPoint(1, linearComb(1.0, p1, -ribbonWidth[ss], flipTestV));        
+
+    p0 = linearComb(2.0, p1, -1, p2);
+    splineCenter.setCPoint(0, p0);
+    splineSide1.setCPoint(0, linearComb(1.0, p0, +ribbonWidth[ss], flipTestV));
+    splineSide2.setCPoint(0, linearComb(1.0, p0, -ribbonWidth[ss], flipTestV));
+  } else {
+    shiftControlPoints();
+    if ((residues.size() - 1 == res) || (residues.size() - 2 == res)) { 
+      // Moving forward along the cp_center[1] - cp_center[2] direction.
+      splineCenter.getCPoint(1, p1);             
+      splineCenter.getCPoint(2, p2);
+
+      p3 = linearComb(2.0, p2, -1, p1);
+      splineCenter.setCPoint(3, p3);
+      splineSide1.setCPoint(3, linearComb(1.0, p3, +ribbonWidth[ss], flipTestV));
+      splineSide2.setCPoint(3, linearComb(1.0, p3, -ribbonWidth[ss], flipTestV));
+    } else {
+      res0 = (HashMap)residues.get(res + 1);
+      res1 = (HashMap)residues.get(res + 2);
+      ca0 = (PVector)res0.get("CA");
+      ox0 = (PVector)res0.get("O");
+      ca1 = (PVector)res1.get("CA");        
+      addControlPoints(ca0, ox0, ca1, ss, handness);
+    }
+  }
+  splineSide1.updateMatrix3();
+  splineCenter.updateMatrix3();
+  splineSide2.updateMatrix3();
+}
+
+PVector linearComb(float scalar0, PVector vector0, float scalar1, PVector vector1) {
+  return PVector.add(PVector.mult(vector0, scalar0), PVector.mult(vector1, scalar1));
+}

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Graphics/Ribbons/PDB.pde

@@ -0,0 +1,115 @@
+void readPDB(String filename) {
+  String strLines[];
+
+  float xmin, xmax, ymin, ymax, zmin, zmax;
+
+  String xstr, ystr, zstr;
+  float x, y, z;
+  int res, res0;
+  int nmdl;
+  String atstr, resstr;
+
+  PShape model;
+  ArrayList atoms;  
+  ArrayList residues;
+  HashMap residue;
+  PVector v;
+  String s;
+  strLines = loadStrings(filename);
+
+  models = new ArrayList();
+
+  xmin = ymin = zmin = 10000;
+  xmax = ymax = zmax = -10000; 
+
+  atoms = null;
+  residues = null;
+  residue = null;
+  model = null;
+  res0 = -1;    
+  nmdl = -1;
+  for (int i = 0; i < strLines.length; i++) {
+    s = strLines[i];
+
+    if (s.startsWith("MODEL") || (s.startsWith("ATOM") && res0 == -1)) {
+      nmdl++;
+
+      res0 = -1;
+
+      atoms = new ArrayList();
+      residues = new ArrayList();
+    }
+
+    if (s.startsWith("ATOM")) {
+      atstr = s.substring(12, 15);
+      atstr = atstr.trim();
+      resstr = s.substring(22, 26);
+      resstr = resstr.trim();
+      res = parseInt(resstr);
+
+      xstr = s.substring(30, 37);
+      xstr = xstr.trim();
+      ystr = s.substring(38, 45);
+      ystr = ystr.trim();            
+      zstr = s.substring(46, 53);
+      zstr = zstr.trim();
+
+      x = scaleFactor * parseFloat(xstr);
+      y = scaleFactor * parseFloat(ystr);
+      z = scaleFactor * parseFloat(zstr);            
+      v = new PVector(x, y, z);
+
+      xmin = min(xmin, x);
+      xmax = max(xmax, x);
+    
+      ymin = min(ymin, y);
+      ymax = max(ymax, y);
+
+      zmin = min(zmin, z);
+      zmax = max(zmax, z);
+
+      atoms.add(v);
+
+      if (res0 != res) {
+        if (residue != null) residues.add(residue);
+        residue = new HashMap();
+      }
+      residue.put(atstr, v);
+
+      res0 = res;
+    }
+
+    if (s.startsWith("ENDMDL") || s.startsWith("TER")) {
+      if (residue != null) residues.add(residue);
+
+      createRibbonModel(residues, model, models);
+      float rgyr = calculateGyrRadius(atoms);
+
+      res0 = -1;
+      residue = null;  
+      atoms = null;
+      residues = null;
+    }
+  }
+
+  if (residue != null) {
+    if (residue != null) residues.add(residue);
+
+    createRibbonModel(residues, model, models);
+    float rgyr = calculateGyrRadius(atoms);
+
+    atoms = null;
+    residues = null;
+  }
+
+  // Centering models at (0, 0, 0).
+  float dx = -0.5f * (xmin + xmax);
+  float dy = -0.5f * (ymin + ymax);
+  float dz = -0.5f * (zmin + zmax);
+  for (int n = 0; n < models.size(); n++) {
+    model = (PShape) models.get(n);
+    model.translate(dx, dy, dz);
+  }
+
+  println("Loaded PDB file with " + models.size() + " models.");
+}

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Graphics/Ribbons/Ribbons.pde

@@ -0,0 +1,51 @@
+// Ribbons, by Andres Colubri
+// ArcBall class by Ariel, V3ga and Robert Hodgin (flight404)
+// This sketch loads 3D atomic coordinates of a protein molecule
+// from a file in PDB format (http://www.pdb.org/) and displays 
+// the structure using a ribbon representation.
+
+String pdbFile = "4HHB.pdb"; // PDB file to read
+//String pdbFile = "1CBS.pdb";
+//String pdbFile = "2POR.pdb";
+
+// Some parameters to control the visual appearance:
+float scaleFactor = 10;          // Size factor
+int renderMode = 1;             // 0 = lines, 1 = flat ribbons
+int ribbonDetail = 4;           // Ribbon detail: from 1 (lowest) to 4 (highest)
+float helixDiam = 10;           // Helix diameter.
+int[] ribbonWidth = {10, 7, 2}; // Ribbon widths for helix, strand and coil
+color ribbonColor = color(0, 102, 153, 255); // Ribbon color
+
+// All the molecular models read from the PDB file (it could contain more than one)
+ArrayList models;
+
+Arcball arcball;
+
+void setup() {
+  size(1024, 768, P3D);
+  
+  arcball = new Arcball(width/2, height/2, 600);  
+  readPDB(pdbFile);
+}
+
+void draw() {
+  background(0);
+   
+  ambient(80);   
+  lights();
+   
+  translate(width/2, height/2, 200);
+  arcball.run();
+
+  for (int i = 0; i < models.size(); i++) {
+    shape((PShape)models.get(i));
+  }
+}
+
+void mousePressed(){
+  arcball.mousePressed();
+}
+
+void mouseDragged(){
+  arcball.mouseDragged();
+}

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Graphics/RotatingArcs/RotatingArcs.pde

@@ -0,0 +1,162 @@
+/**
+ * Geometry 
+ * by Marius Watz. 
+ * 
+ * Using sin/cos lookup tables, blends colors, and draws a series of 
+ * rotating arcs on the screen.
+*/
+ 
+// Trig lookup tables borrowed from Toxi; cryptic but effective.
+float sinLUT[];
+float cosLUT[];
+float SINCOS_PRECISION=1.0;
+int SINCOS_LENGTH= int((360.0/SINCOS_PRECISION));
+ 
+// System data
+boolean dosave=false;
+int num;
+float pt[];
+int style[];
+
+ 
+void setup() {
+  size(1024, 768, P3D);
+  background(255);
+  
+  // Fill the tables
+  sinLUT=new float[SINCOS_LENGTH];
+  cosLUT=new float[SINCOS_LENGTH];
+  for (int i = 0; i < SINCOS_LENGTH; i++) {
+    sinLUT[i]= (float)Math.sin(i*DEG_TO_RAD*SINCOS_PRECISION);
+    cosLUT[i]= (float)Math.cos(i*DEG_TO_RAD*SINCOS_PRECISION);
+  }
+ 
+  num = 150;
+  pt = new float[6*num]; // rotx, roty, deg, rad, w, speed
+  style = new int[2*num]; // color, render style
+ 
+  // Set up arc shapes
+  int index=0;
+  float prob;
+  for (int i=0; i<num; i++) {
+    pt[index++] = random(PI*2); // Random X axis rotation
+    pt[index++] = random(PI*2); // Random Y axis rotation
+ 
+    pt[index++] = random(60,80); // Short to quarter-circle arcs
+    if(random(100)>90) pt[index]=(int)random(8,27)*10;
+ 
+    pt[index++] = int(random(2,50)*5); // Radius. Space them out nicely
+ 
+    pt[index++] = random(4,32); // Width of band
+    if(random(100)>90) pt[index]=random(40,60); // Width of band
+ 
+    pt[index++] = radians(random(5,30))/5; // Speed of rotation
+ 
+    // get colors
+    prob = random(100);
+    if(prob<30) style[i*2]=colorBlended(random(1), 255,0,100, 255,0,0, 210);
+    else if(prob<70) style[i*2]=colorBlended(random(1), 0,153,255, 170,225,255, 210);
+    else if(prob<90) style[i*2]=colorBlended(random(1), 200,255,0, 150,255,0, 210);
+    else style[i*2]=color(255,255,255, 220);
+
+    if(prob<50) style[i*2]=colorBlended(random(1), 200,255,0, 50,120,0, 210);
+    else if(prob<90) style[i*2]=colorBlended(random(1), 255,100,0, 255,255,0, 210);
+    else style[i*2]=color(255,255,255, 220);
+
+    style[i*2+1]=(int)(random(100))%3;
+  }
+}
+ 
+void draw() {
+ 
+  background(0);
+ 
+  int index=0;
+  translate(width/2, height/2, 0);
+  rotateX(PI/6);
+  rotateY(PI/6);
+ 
+  for (int i = 0; i < num; i++) {
+    pushMatrix();
+ 
+    rotateX(pt[index++]);
+    rotateY(pt[index++]);
+ 
+    if(style[i*2+1]==0) {
+      stroke(style[i*2]);
+      noFill();
+      strokeWeight(1);
+      arcLine(0,0, pt[index++],pt[index++],pt[index++]);
+    }
+    else if(style[i*2+1]==1) {
+      fill(style[i*2]);
+      noStroke();
+      arcLineBars(0,0, pt[index++],pt[index++],pt[index++]);
+    }
+    else {
+      fill(style[i*2]);
+      noStroke();
+      arc(0,0, pt[index++],pt[index++],pt[index++]);
+    }
+ 
+    // increase rotation
+    pt[index-5]+=pt[index]/10;
+    pt[index-4]+=pt[index++]/20;
+ 
+    popMatrix();
+  }
+}
+ 
+ 
+// Get blend of two colors
+int colorBlended(float fract,
+float r, float g, float b,
+float r2, float g2, float b2, float a) {
+ 
+  r2 = (r2 - r);
+  g2 = (g2 - g);
+  b2 = (b2 - b);
+  return color(r + r2 * fract, g + g2 * fract, b + b2 * fract, a);
+}
+ 
+ 
+// Draw arc line
+void arcLine(float x,float y,float deg,float rad,float w) {
+  int a=(int)(min (deg/SINCOS_PRECISION,SINCOS_LENGTH-1));
+  int numlines=(int)(w/2);
+ 
+  for (int j=0; j<numlines; j++) {
+    beginShape();
+    for (int i=0; i<a; i++) { 
+      vertex(cosLUT[i]*rad+x,sinLUT[i]*rad+y);
+    }
+    endShape();
+    rad += 2;
+  }
+}
+ 
+// Draw arc line with bars
+void arcLineBars(float x,float y,float deg,float rad,float w) {
+  int a = int((min (deg/SINCOS_PRECISION,SINCOS_LENGTH-1)));
+  a /= 4;
+ 
+  beginShape(QUADS);
+  for (int i=0; i<a; i+=4) {
+    vertex(cosLUT[i]*(rad)+x,sinLUT[i]*(rad)+y);
+    vertex(cosLUT[i]*(rad+w)+x,sinLUT[i]*(rad+w)+y);
+    vertex(cosLUT[i+2]*(rad+w)+x,sinLUT[i+2]*(rad+w)+y);
+    vertex(cosLUT[i+2]*(rad)+x,sinLUT[i+2]*(rad)+y);
+  }
+  endShape();
+}
+ 
+// Draw solid arc
+void arc(float x,float y,float deg,float rad,float w) {
+  int a = int(min (deg/SINCOS_PRECISION,SINCOS_LENGTH-1));
+  beginShape(QUAD_STRIP);
+  for (int i = 0; i < a; i++) {
+    vertex(cosLUT[i]*(rad)+x,sinLUT[i]*(rad)+y);
+    vertex(cosLUT[i]*(rad+w)+x,sinLUT[i]*(rad+w)+y);
+  }
+  endShape();
+}

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Graphics/Trefoil/Surface.pde

@@ -0,0 +1,105 @@
+// Code to draw a trefoil knot surface, with normals and texture 
+// coordinates.
+// Adapted from the parametric equations example by Philip Rideout:
+// http://iphone-3d-programming.labs.oreilly.com/ch03.html
+
+// This function draws a trefoil knot surface as a triangle mesh derived
+// from its parametric equation.
+PShape createTrefoil(float s, int ny, int nx, PImage tex) {
+  PVector p0, p1, p2;
+  PVector n0, n1, n2;
+  float u0, u1, v0, v1;
+  
+  PShape obj = createShape();
+  obj.beginShape(TRIANGLES);
+  obj.texture(tex);
+    
+  for (int j = 0; j < nx; j++) {
+    u0 = float(j) / nx;
+    u1 = float(j + 1) / nx;
+    for (int i = 0; i < ny; i++) {
+      v0 = float(i) / ny;
+      v1 = float(i + 1) / ny;
+      
+      p0 = evalPoint(u0, v0);
+      n0 = evalNormal(u0, v0);
+      
+      p1 = evalPoint(u0, v1);
+      n1 = evalNormal(u0, v1);
+      
+      p2 = evalPoint(u1, v1);
+      n2 = evalNormal(u1, v1);
+
+      // Triangle p0-p1-p2      
+      obj.normal(n0.x, n0.y, n0.z);
+      obj.vertex(s * p0.x, s * p0.y, s * p0.z, u0, v0);      
+      obj.normal(n1.x, n1.y, n1.z);
+      obj.vertex(s * p1.x, s * p1.y, s * p1.z, u0, v1);
+      obj.normal(n2.x, n2.y, n2.z);
+      obj.vertex(s * p2.x, s * p2.y, s * p2.z, u1, v1);
+
+      p1 = evalPoint(u1, v0);
+      n1 = evalNormal(u1, v0);
+
+      // Triangle p0-p2-p1      
+      obj.normal(n0.x, n0.y, n0.z);
+      obj.vertex(s * p0.x, s * p0.y, s * p0.z, u0, v0);      
+      obj.normal(n2.x, n2.y, n2.z);
+      obj.vertex(s * p2.x, s * p2.y, s * p2.z, u1, v1);
+      obj.normal(n1.x, n1.y, n1.z);
+      obj.vertex(s * p1.x, s * p1.y, s * p1.z, u1, v0);      
+    }
+  }
+  obj.endShape();
+  return obj;
+}
+
+// Evaluates the surface normal corresponding to normalized 
+// parameters (u, v)
+PVector evalNormal(float u, float v) {
+  // Compute the tangents and their cross product.
+  PVector p = evalPoint(u, v);
+  PVector tangU = evalPoint(u + 0.01, v);
+  PVector tangV = evalPoint(u, v + 0.01);
+  tangU.sub(p);
+  tangV.sub(p);
+  
+  PVector normUV = tangV.cross(tangU);
+  normUV.normalize();
+  return normUV;
+}
+
+// Evaluates the surface point corresponding to normalized 
+// parameters (u, v)
+PVector evalPoint(float u, float v) {
+  float a = 0.5;
+  float b = 0.3;
+  float c = 0.5;
+  float d = 0.1;
+  float s = TWO_PI * u;
+  float t = (TWO_PI * (1 - v)) * 2;  
+        
+  float r = a + b * cos(1.5 * t);
+  float x = r * cos(t);
+  float y = r * sin(t);
+  float z = c * sin(1.5 * t);
+        
+  PVector dv = new PVector();
+  dv.x = -1.5 * b * sin(1.5 * t) * cos(t) -
+         (a + b * cos(1.5 * t)) * sin(t);
+  dv.y = -1.5 * b * sin(1.5 * t) * sin(t) +
+         (a + b * cos(1.5 * t)) * cos(t);
+  dv.z = 1.5 * c * cos(1.5 * t);
+        
+  PVector q = dv;      
+  q.normalize();
+  PVector qvn = new PVector(q.y, -q.x, 0);
+  qvn.normalize();
+  PVector ww = q.cross(qvn);
+        
+  PVector pt = new PVector();
+  pt.x = x + d * (qvn.x * cos(s) + ww.x * sin(s));
+  pt.y = y + d * (qvn.y * cos(s) + ww.y * sin(s));
+  pt.z = z + d * ww.z * sin(s);
+  return pt;
+}

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Graphics/Trefoil/Trefoil.pde

@@ -0,0 +1,42 @@
+// Trefoil, by Andres Colubri
+// A parametric surface is textured procedurally
+// by drawing on an offscreen PGraphics surface.
+
+PGraphics pg;
+PShape trefoil;
+
+void setup() {
+  size(1024, 768, P3D);
+  
+  textureMode(NORMAL);
+  noStroke();
+
+  // Creating offscreen surface for 3D rendering.
+  pg = createGraphics(32, 512, P3D);
+  pg.beginDraw();
+  pg.background(0, 0);
+  pg.noStroke();
+  pg.fill(255, 0, 0, 200);
+  pg.endDraw(); 
+
+  // Saving trefoil surface into a PShape3D object
+  trefoil = createTrefoil(350, 60, 15, pg);
+}
+
+void draw() {
+  background(0);
+  
+  pg.beginDraw();    
+  pg.ellipse(random(pg.width), random(pg.height), 4, 4);
+  pg.endDraw(); 
+
+  ambient(250, 250, 250);
+  pointLight(255, 255, 255, 0, 0, 200);
+     
+  pushMatrix();
+  translate(width/2, height/2, -200);
+  rotateX(frameCount * PI / 500);
+  rotateY(frameCount * PI / 500);      
+  shape(trefoil);
+  popMatrix();
+}

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Graphics/Wiggling/Wiggling.pde

@@ -0,0 +1,143 @@
+// Press 'w' to start wiggling, space to restore
+// original positions.
+
+PShape cube;
+float cubeSize = 320;
+float circleRad = 100;
+int circleRes = 40;
+float noiseMag = 1;
+
+boolean wiggling = false;
+
+void setup() {
+  size(1024, 768, P3D);    
+
+  createCube();
+}
+
+void draw() {
+  background(0);
+
+  translate(width/2, height/2);
+  rotateX(frameCount * 0.01f);
+  rotateY(frameCount * 0.01f);
+
+  shape(cube);
+
+  if (wiggling) {
+    PVector pos = null;
+    for (int i = 0; i < cube.getChildCount(); i++) {
+      PShape face = cube.getChild(i);
+      for (int j = 0; j < face.getVertexCount(); j++) {
+        pos = face.getVertex(j, pos);
+        pos.x += random(-noiseMag/2, +noiseMag/2);
+        pos.y += random(-noiseMag/2, +noiseMag/2);
+        pos.z += random(-noiseMag/2, +noiseMag/2);
+        face.setVertex(j, pos.x, pos.y, pos.z);
+      }
+    }
+  }
+
+  if (frameCount % 60 == 0) println(frameRate);
+}
+
+public void keyPressed() {
+  if (key == 'w') {
+    wiggling = !wiggling;
+  } else if (key == ' ') {
+    restoreCube();
+  } else if (key == '1') {
+    cube.setStrokeWeight(1);
+  } else if (key == '2') {
+    cube.setStrokeWeight(5);
+  } else if (key == '3') {
+    cube.setStrokeWeight(10);
+  }
+}
+
+void createCube() {
+  cube = createShape(GROUP);  
+
+  PShape face;
+
+  // Create all faces at front position
+  for (int i = 0; i < 6; i++) {
+    face = createShape();
+    createFaceWithHole(face);
+    cube.addChild(face);
+  }
+
+  // Rotate all the faces to their positions
+
+  // Front face - already correct
+  face = cube.getChild(0);
+
+  // Back face
+  face = cube.getChild(1);
+  face.rotateY(radians(180));
+
+  // Right face
+  face = cube.getChild(2);
+  face.rotateY(radians(90));
+
+  // Left face
+  face = cube.getChild(3);
+  face.rotateY(radians(-90));
+
+  // Top face
+  face = cube.getChild(4);
+  face.rotateX(radians(90));
+
+  // Bottom face
+  face = cube.getChild(5);
+  face.rotateX(radians(-90));
+}
+
+void createFaceWithHole(PShape face) {
+  face.beginShape(POLYGON);
+  face.stroke(255, 0, 0);
+  face.fill(255);
+
+  // Draw main shape Clockwise
+  face.vertex(-cubeSize/2, -cubeSize/2, +cubeSize/2);
+  face.vertex(+cubeSize/2, -cubeSize/2, +cubeSize/2);
+  face.vertex(+cubeSize/2, +cubeSize/2, +cubeSize/2);
+  face.vertex(-cubeSize / 2, +cubeSize / 2, +cubeSize / 2);
+
+  // Draw contour (hole) Counter-Clockwise
+  face.beginContour();
+  for (int i = 0; i < circleRes; i++) {
+    float angle = TWO_PI * i / circleRes;
+    float x = circleRad * sin(angle);
+    float y = circleRad * cos(angle);
+    float z = +cubeSize/2;
+    face.vertex(x, y, z);
+  }
+  face.endContour();
+
+  face.endShape(CLOSE);
+}
+
+void restoreCube() {
+  // Rotation of faces is preserved, so we just reset them
+  // the same way as the "front" face and they will stay
+  // rotated correctly
+  for (int i = 0; i < 6; i++) {
+    PShape face = cube.getChild(i);
+    restoreFaceWithHole(face);
+  }
+}
+
+void restoreFaceWithHole(PShape face) {
+  face.setVertex(0, -cubeSize/2, -cubeSize/2, +cubeSize/2);
+  face.setVertex(1, +cubeSize/2, -cubeSize/2, +cubeSize/2);
+  face.setVertex(2, +cubeSize/2, +cubeSize/2, +cubeSize/2);
+  face.setVertex(3, -cubeSize/2, +cubeSize/2, +cubeSize/2);
+  for (int i = 0; i < circleRes; i++) {
+    float angle = TWO_PI * i / circleRes;
+    float x = circleRad * sin(angle);
+    float y = circleRad * cos(angle);
+    float z = +cubeSize/2;
+    face.setVertex(4 + i, x, y, z);
+  }
+}

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Graphics/Yellowtail/Gesture.pde

@@ -0,0 +1,256 @@
+class Gesture {
+
+  float  damp = 5.0;
+  float  dampInv = 1.0 / damp;
+  float  damp1 = damp - 1;
+
+  int w;
+  int h;
+  int capacity;
+
+  Vec3f path[];
+  int crosses[];
+  Polygon polygons[];
+  int nPoints;
+  int nPolys;
+
+  float jumpDx, jumpDy;
+  boolean exists;
+  float INIT_TH = 14;
+  float thickness = INIT_TH;
+
+  Gesture(int mw, int mh) {
+    w = mw;
+    h = mh;
+    capacity = 600;
+    path = new Vec3f[capacity];
+    polygons = new Polygon[capacity];
+    crosses  = new int[capacity];
+    for (int i=0;i<capacity;i++) {
+      polygons[i] = new Polygon();
+      polygons[i].npoints = 4;
+      path[i] = new Vec3f();
+      crosses[i] = 0;
+    }
+    nPoints = 0;
+    nPolys = 0;
+
+    exists = false;
+    jumpDx = 0;
+    jumpDy = 0;
+  }
+
+  void clear() {
+    nPoints = 0;
+    exists = false;
+    thickness = INIT_TH;
+  }
+
+  void clearPolys() {
+    nPolys = 0;
+  }
+
+  void addPoint(float x, float y) {
+
+    if (nPoints >= capacity) {
+      // there are all sorts of possible solutions here,
+      // but for abject simplicity, I don't do anything.
+    } 
+    else {
+      float v = distToLast(x, y);
+      float p = getPressureFromVelocity(v);
+      path[nPoints++].set(x,y,p);
+
+      if (nPoints > 1) {
+        exists = true;
+        jumpDx = path[nPoints-1].x - path[0].x;
+        jumpDy = path[nPoints-1].y - path[0].y;
+      }
+    }
+
+  }
+
+  float getPressureFromVelocity(float v) {
+    final float scale = 18;
+    final float minP = 0.02;
+    final float oldP = (nPoints > 0) ? path[nPoints-1].p : 0;
+    return ((minP + max(0, 1.0 - v/scale)) + (damp1*oldP))*dampInv;
+  }
+
+  void setPressures() {
+    // pressures vary from 0...1
+    float pressure;
+    Vec3f tmp;
+    float t = 0;
+    float u = 1.0 / (nPoints - 1)*TWO_PI;
+    for (int i = 0; i < nPoints; i++) {
+      pressure = sqrt((1.0 - cos(t))*0.5);
+      path[i].p = pressure;
+      t += u;
+    }
+  }
+
+  float distToLast(float ix, float iy) {
+    if (nPoints > 0) {
+      Vec3f v = path[nPoints-1];
+      float dx = v.x - ix;
+      float dy = v.y - iy;
+      return mag(dx, dy);
+    } 
+    else {
+      return 30;
+    }
+  }
+
+  void compile() {
+    // compute the polygons from the path of Vec3f's
+    if (exists) {
+      clearPolys();
+
+      Vec3f p0, p1, p2;
+      float radius0, radius1;
+      float ax, bx, cx, dx;
+      float ay, by, cy, dy;
+      int   axi, bxi, cxi, dxi, axip, axid;
+      int   ayi, byi, cyi, dyi, ayip, ayid;
+      float p1x, p1y;
+      float dx01, dy01, hp01, si01, co01;
+      float dx02, dy02, hp02, si02, co02;
+      float dx13, dy13, hp13, si13, co13;
+      float taper = 1.0;
+
+      int  nPathPoints = nPoints - 1;
+      int  lastPolyIndex = nPathPoints - 1;
+      float npm1finv =  1.0 / max(1, nPathPoints - 1);
+
+      // handle the first point
+      p0 = path[0];
+      p1 = path[1];
+      radius0 = p0.p * thickness;
+      dx01 = p1.x - p0.x;
+      dy01 = p1.y - p0.y;
+      hp01 = sqrt(dx01*dx01 + dy01*dy01);
+      if (hp01 == 0) {
+        hp02 = 0.0001;
+      }
+      co01 = radius0 * dx01 / hp01;
+      si01 = radius0 * dy01 / hp01;
+      ax = p0.x - si01; 
+      ay = p0.y + co01;
+      bx = p0.x + si01; 
+      by = p0.y - co01;
+
+      int xpts[];
+      int ypts[];
+
+      int LC = 20;
+      int RC = w-LC;
+      int TC = 20;
+      int BC = h-TC;
+      float mint = 0.618;
+      float tapow = 0.4;
+
+      // handle the middle points
+      int i = 1;
+      Polygon apoly;
+      for (i = 1; i < nPathPoints; i++) {
+        taper = pow((lastPolyIndex-i)*npm1finv,tapow);
+
+        p0 = path[i-1];
+        p1 = path[i  ];
+        p2 = path[i+1];
+        p1x = p1.x;
+        p1y = p1.y;
+        radius1 = Math.max(mint,taper*p1.p*thickness);
+
+        // assumes all segments are roughly the same length...
+        dx02 = p2.x - p0.x;
+        dy02 = p2.y - p0.y;
+        hp02 = (float) Math.sqrt(dx02*dx02 + dy02*dy02);
+        if (hp02 != 0) {
+          hp02 = radius1/hp02;
+        }
+        co02 = dx02 * hp02;
+        si02 = dy02 * hp02;
+
+        // translate the integer coordinates to the viewing rectangle
+        axi = axip = (int)ax;
+        ayi = ayip = (int)ay;
+        axi=(axi<0)?(w-((-axi)%w)):axi%w;
+        axid = axi-axip;
+        ayi=(ayi<0)?(h-((-ayi)%h)):ayi%h;
+        ayid = ayi-ayip;
+
+        // set the vertices of the polygon
+        apoly = polygons[nPolys++];
+        xpts = apoly.xpoints;
+        ypts = apoly.ypoints;
+        xpts[0] = axi = axid + axip;
+        xpts[1] = bxi = axid + (int) bx;
+        xpts[2] = cxi = axid + (int)(cx = p1x + si02);
+        xpts[3] = dxi = axid + (int)(dx = p1x - si02);
+        ypts[0] = ayi = ayid + ayip;
+        ypts[1] = byi = ayid + (int) by;
+        ypts[2] = cyi = ayid + (int)(cy = p1y - co02);
+        ypts[3] = dyi = ayid + (int)(dy = p1y + co02);
+
+        // keep a record of where we cross the edge of the screen
+        crosses[i] = 0;
+        if ((axi<=LC)||(bxi<=LC)||(cxi<=LC)||(dxi<=LC)) { 
+          crosses[i]|=1; 
+        }
+        if ((axi>=RC)||(bxi>=RC)||(cxi>=RC)||(dxi>=RC)) { 
+          crosses[i]|=2; 
+        }
+        if ((ayi<=TC)||(byi<=TC)||(cyi<=TC)||(dyi<=TC)) { 
+          crosses[i]|=4; 
+        }
+        if ((ayi>=BC)||(byi>=BC)||(cyi>=BC)||(dyi>=BC)) { 
+          crosses[i]|=8; 
+        }
+
+        //swap data for next time
+        ax = dx; 
+        ay = dy;
+        bx = cx; 
+        by = cy;
+      }
+
+      // handle the last point
+      p2 = path[nPathPoints];
+      apoly = polygons[nPolys++];
+      xpts = apoly.xpoints;
+      ypts = apoly.ypoints;
+
+      xpts[0] = (int)ax;
+      xpts[1] = (int)bx;
+      xpts[2] = (int)(p2.x);
+      xpts[3] = (int)(p2.x);
+
+      ypts[0] = (int)ay;
+      ypts[1] = (int)by;
+      ypts[2] = (int)(p2.y);
+      ypts[3] = (int)(p2.y);
+
+    }
+  }
+
+  void smooth() {
+    // average neighboring points
+
+    final float weight = 18;
+    final float scale  = 1.0 / (weight + 2);
+    int nPointsMinusTwo = nPoints - 2;
+    Vec3f lower, upper, center;
+
+    for (int i = 1; i < nPointsMinusTwo; i++) {
+      lower = path[i-1];
+      center = path[i];
+      upper = path[i+1];
+
+      center.x = (lower.x + weight*center.x + upper.x)*scale;
+      center.y = (lower.y + weight*center.y + upper.y)*scale;
+    }
+  }
+}
+

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Graphics/Yellowtail/Vec3f.pde

@@ -0,0 +1,19 @@
+class Vec3f {
+  float x;
+  float y;
+  float p;  // Pressure
+
+  Vec3f() {
+    set(0, 0, 0);
+  }
+  
+  Vec3f(float ix, float iy, float ip) {
+    set(ix, iy, ip);
+  }
+
+  void set(float ix, float iy, float ip) {
+    x = ix;
+    y = iy;
+    p = ip;
+  }
+}

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Graphics/Yellowtail/Yellowtail.pde

@@ -0,0 +1,189 @@
+/**
+ * Yellowtail
+ * by Golan Levin (www.flong.com). 
+ * 
+ * Click, drag, and release to create a kinetic gesture.
+ * 
+ * Yellowtail (1998-2000) is an interactive software system for the gestural 
+ * creation and performance of real-time abstract animation. Yellowtail repeats 
+ * a user's strokes end-over-end, enabling simultaneous specification of a 
+ * line's shape and quality of movement. Each line repeats according to its 
+ * own period, producing an ever-changing and responsive display of lively, 
+ * worm-like textures.
+ */
+
+
+import java.awt.Polygon;
+
+Gesture gestureArray[];
+final int nGestures = 36;  // Number of gestures
+final int minMove = 3;     // Minimum travel for a new point
+int currentGestureID;
+
+Polygon tempP;
+int tmpXp[];
+int tmpYp[];
+
+
+void setup() {
+  size(1024, 768, P2D);
+  background(0, 0, 0);
+  noStroke();
+
+  currentGestureID = -1;
+  gestureArray = new Gesture[nGestures];
+  for (int i = 0; i < nGestures; i++) {
+    gestureArray[i] = new Gesture(width, height);
+  }
+  clearGestures();
+}
+
+
+void draw() {
+  background(0);
+
+  updateGeometry();
+  fill(255, 255, 245);
+  for (int i = 0; i < nGestures; i++) {
+    renderGesture(gestureArray[i], width, height);
+  }
+}
+
+void mousePressed() {
+  currentGestureID = (currentGestureID+1) % nGestures;
+  Gesture G = gestureArray[currentGestureID];
+  G.clear();
+  G.clearPolys();
+  G.addPoint(mouseX, mouseY);
+}
+
+
+void mouseDragged() {
+  if (currentGestureID >= 0) {
+    Gesture G = gestureArray[currentGestureID];
+    if (G.distToLast(mouseX, mouseY) > minMove) {
+      G.addPoint(mouseX, mouseY);
+      G.smooth();
+      G.compile();
+    }
+  }
+}
+
+
+void keyPressed() {
+  if (key == '+' || key == '=') {
+    if (currentGestureID >= 0) {
+      float th = gestureArray[currentGestureID].thickness;
+      gestureArray[currentGestureID].thickness = min(96, th+1);
+      gestureArray[currentGestureID].compile();
+    }
+  } else if (key == '-') {
+    if (currentGestureID >= 0) {
+      float th = gestureArray[currentGestureID].thickness;
+      gestureArray[currentGestureID].thickness = max(2, th-1);
+      gestureArray[currentGestureID].compile();
+    }
+  } else if (key == ' ') {
+    clearGestures();
+  }
+}
+
+
+void renderGesture(Gesture gesture, int w, int h) {
+  if (gesture.exists) {
+    if (gesture.nPolys > 0) {
+      Polygon polygons[] = gesture.polygons;
+      int crosses[] = gesture.crosses;
+
+      int xpts[];
+      int ypts[];
+      Polygon p;
+      int cr;
+
+      beginShape(QUADS);
+      int gnp = gesture.nPolys;
+      for (int i=0; i<gnp; i++) {
+
+        p = polygons[i];
+        xpts = p.xpoints;
+        ypts = p.ypoints;
+
+        vertex(xpts[0], ypts[0]);
+        vertex(xpts[1], ypts[1]);
+        vertex(xpts[2], ypts[2]);
+        vertex(xpts[3], ypts[3]);
+
+        if ((cr = crosses[i]) > 0) {
+          if ((cr & 3)>0) {
+            vertex(xpts[0]+w, ypts[0]);
+            vertex(xpts[1]+w, ypts[1]);
+            vertex(xpts[2]+w, ypts[2]);
+            vertex(xpts[3]+w, ypts[3]);
+
+            vertex(xpts[0]-w, ypts[0]);
+            vertex(xpts[1]-w, ypts[1]);
+            vertex(xpts[2]-w, ypts[2]);
+            vertex(xpts[3]-w, ypts[3]);
+          }
+          if ((cr & 12)>0) {
+            vertex(xpts[0], ypts[0]+h);
+            vertex(xpts[1], ypts[1]+h);
+            vertex(xpts[2], ypts[2]+h);
+            vertex(xpts[3], ypts[3]+h);
+
+            vertex(xpts[0], ypts[0]-h);
+            vertex(xpts[1], ypts[1]-h);
+            vertex(xpts[2], ypts[2]-h);
+            vertex(xpts[3], ypts[3]-h);
+          }
+
+          // I have knowingly retained the small flaw of not
+          // completely dealing with the corner conditions
+          // (the case in which both of the above are true).
+        }
+      }
+      endShape();
+    }
+  }
+}
+
+void updateGeometry() {
+  Gesture J;
+  for (int g=0; g<nGestures; g++) {
+    if ((J=gestureArray[g]).exists) {
+      if (g!=currentGestureID) {
+        advanceGesture(J);
+      } else if (!mousePressed) {
+        advanceGesture(J);
+      }
+    }
+  }
+}
+
+void advanceGesture(Gesture gesture) {
+  // Move a Gesture one step
+  if (gesture.exists) { // check
+    int nPts = gesture.nPoints;
+    int nPts1 = nPts-1;
+    Vec3f path[];
+    float jx = gesture.jumpDx;
+    float jy = gesture.jumpDy;
+
+    if (nPts > 0) {
+      path = gesture.path;
+      for (int i = nPts1; i > 0; i--) {
+        path[i].x = path[i-1].x;
+        path[i].y = path[i-1].y;
+      }
+      path[0].x = path[nPts1].x - jx;
+      path[0].y = path[nPts1].y - jy;
+      gesture.compile();
+    }
+  }
+}
+
+void clearGestures() {
+  for (int i = 0; i < nGestures; i++) {
+    gestureArray[i].clear();
+  }
+}

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Performance/CubicGridImmediate/CubicGridImmediate.pde

@@ -0,0 +1,65 @@
+/**
+ * Cubic Grid 
+ * by Ira Greenberg. 
+ * 
+ * 3D translucent colored grid uses nested pushMatrix()
+ * and popMatrix() functions. 
+ */
+
+float boxSize = 20;
+float margin = boxSize*2;
+float depth = 400;
+color boxFill;
+
+int fcount, lastm;
+float frate;
+int fint = 3;
+
+void setup() {
+  size(640, 360, P3D);
+  frameRate(60);
+  noSmooth();
+  noStroke();
+}
+
+void draw() {
+  background(255);
+  
+  hint(DISABLE_DEPTH_TEST);
+    
+  // Center and spin grid
+  pushMatrix();
+  translate(width/2, height/2, -depth);
+  rotateY(frameCount * 0.01);
+  rotateX(frameCount * 0.01);
+
+  // Build grid using multiple translations 
+  for (float i =- depth/2+margin; i <= depth/2-margin; i += boxSize){
+    for (float j =- height+margin; j <= height-margin; j += boxSize){
+      for (float k =- width+margin; k <= width-margin; k += boxSize){
+        // Base fill color on counter values, abs function 
+        // ensures values stay within legal range
+        boxFill = color(abs(i), abs(j), abs(k), 50);
+        pushMatrix();
+        translate(k, j, i);
+        fill(boxFill);
+        box(boxSize, boxSize, boxSize);
+        popMatrix();
+      }
+    }
+  }
+  popMatrix();
+  
+  hint(ENABLE_DEPTH_TEST);
+  
+  fcount += 1;
+  int m = millis();
+  if (m - lastm > 1000 * fint) {
+    frate = float(fcount) / fint;
+    fcount = 0;
+    lastm = m;
+    println("fps: " + frate); 
+  }
+  fill(0);
+  text("fps: " + frate, 10, 20);  
+}

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Performance/CubicGridRetained/CubicGridRetained.pde

@@ -0,0 +1,67 @@
+/* CubicGridRetained
+ *
+ * You may need to increase the maximum available memory in the
+ * Processing preferences menu.
+*/
+float boxSize = 20;
+float margin = boxSize*2;
+float depth = 400;
+color boxFill;
+
+PShape grid;
+
+int fcount, lastm;
+float frate;
+int fint = 3;
+
+void setup() {
+  size(640, 360, P3D);
+  frameRate(60);
+  noSmooth();
+  noStroke();
+
+  grid = createShape(GROUP);
+
+  // Build grid using multiple translations
+  for (float i =- depth/2+margin; i <= depth/2-margin; i += boxSize){
+    for (float j =- height+margin; j <= height-margin; j += boxSize){
+      for (float k =- width+margin; k <= width-margin; k += boxSize){
+        // Base fill color on counter values, abs function
+        // ensures values stay within legal range
+        boxFill = color(abs(i), abs(j), abs(k), 50);
+        PShape cube = createShape(BOX, boxSize, boxSize, boxSize);
+        cube.setFill(boxFill);
+        cube.translate(k, j, i);
+        grid.addChild(cube);
+      }
+    }
+  }
+}
+
+void draw() {
+  background(255);
+
+  hint(DISABLE_DEPTH_TEST);
+
+  // Center and spin grid
+  pushMatrix();
+  translate(width/2, height/2, -depth);
+  rotateY(frameCount * 0.01);
+  rotateX(frameCount * 0.01);
+
+  shape(grid);
+  popMatrix();
+
+  hint(ENABLE_DEPTH_TEST);
+
+  fcount += 1;
+  int m = millis();
+  if (m - lastm > 1000 * fint) {
+    frate = float(fcount) / fint;
+    fcount = 0;
+    lastm = m;
+    println("fps: " + frate);
+  }
+  fill(0);
+  text("fps: " + frate, 10, 20);
+}

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Performance/DynamicParticlesImmediate/DynamicParticlesImmediate.pde

@@ -0,0 +1,118 @@
+PImage sprite;  
+
+int npartTotal = 10000;
+int npartPerFrame = 25;
+float speed = 1.0;
+float gravity = 0.05;
+float partSize = 20;
+
+int partLifetime;
+PVector positions[];
+PVector velocities[];
+int lifetimes[];  
+
+int fcount, lastm;
+float frate;
+int fint = 3;
+
+void setup() {
+  size(640, 480, P3D);
+  frameRate(120);
+  
+  sprite = loadImage("sprite.png");
+
+  partLifetime = npartTotal / npartPerFrame;
+  initPositions();
+  initVelocities();
+  initLifetimes(); 
+
+  // Writing to the depth buffer is disabled to avoid rendering
+  // artifacts due to the fact that the particles are semi-transparent
+  // but not z-sorted.
+  hint(DISABLE_DEPTH_MASK);
+  
+  // Testing some hints
+  //hint(DISABLE_TRANSFORM_CACHE);
+  //hint(ENABLE_ACCURATE_2D);
+} 
+
+void draw () {
+  background(0);
+
+  for (int n = 0; n < npartTotal; n++) {
+    lifetimes[n]++;
+    if (lifetimes[n] == partLifetime) {
+      lifetimes[n] = 0;
+    }      
+
+    if (0 <= lifetimes[n]) {      
+      float opacity = 1.0 - float(lifetimes[n]) / partLifetime;
+            
+      if (lifetimes[n] == 0) {
+        // Re-spawn dead particle
+        positions[n].x = mouseX;
+        positions[n].y = mouseY;
+        
+        float angle = random(0, TWO_PI);
+        float s = random(0.5 * speed, 0.5 * speed);
+        velocities[n].x = s * cos(angle);
+        velocities[n].y = s * sin(angle);
+      } else {
+        positions[n].x += velocities[n].x;
+        positions[n].y += velocities[n].y;
+        
+        velocities[n].y += gravity;
+      }
+      drawParticle(positions[n], opacity);
+    }
+  }
+  
+  fcount += 1;
+  int m = millis();
+  if (m - lastm > 1000 * fint) {
+    frate = float(fcount) / fint;
+    fcount = 0;
+    lastm = m;
+    println("fps: " + frate); 
+  } 
+}
+
+void drawParticle(PVector center, float opacity) {
+  beginShape(QUAD);
+  noStroke();
+  tint(255, opacity * 255);
+  texture(sprite);
+  normal(0, 0, 1);
+  vertex(center.x - partSize/2, center.y - partSize/2, 0, 0);
+  vertex(center.x + partSize/2, center.y - partSize/2, sprite.width, 0);
+  vertex(center.x + partSize/2, center.y + partSize/2, sprite.width, sprite.height);
+  vertex(center.x - partSize/2, center.y + partSize/2, 0, sprite.height);                
+  endShape();  
+}
+
+void initPositions() {
+  positions = new PVector[npartTotal];
+  for (int n = 0; n < positions.length; n++) {
+    positions[n] = new PVector();
+  }  
+}
+
+void initVelocities() {
+  velocities = new PVector[npartTotal];
+  for (int n = 0; n < velocities.length; n++) {
+    velocities[n] = new PVector();
+  }
+}
+
+void initLifetimes() {
+  // Initializing particles with negative lifetimes so they are added
+  // progressively into the screen during the first frames of the sketch   
+  lifetimes = new int[npartTotal];
+  int t = -1;
+  for (int n = 0; n < lifetimes.length; n++) {    
+    if (n % npartPerFrame == 0) {
+      t++;
+    }
+    lifetimes[n] = -t;
+  }
+} 

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Performance/DynamicParticlesRetained/DynamicParticlesRetained.pde

@@ -0,0 +1,111 @@
+PShape particles;
+PImage sprite;  
+
+int npartTotal = 10000;
+int npartPerFrame = 25;
+float speed = 1.0;
+float gravity = 0.05;
+float partSize = 20;
+
+int partLifetime;
+PVector velocities[];
+int lifetimes[];
+
+int fcount, lastm;
+float frate;
+int fint = 3;
+
+void setup() {
+  size(640, 480, P3D);
+  frameRate(120);
+
+  particles = createShape(PShape.GROUP);
+  sprite = loadImage("sprite.png");
+
+  for (int n = 0; n < npartTotal; n++) {
+    PShape part = createShape();
+    part.beginShape(QUAD);
+    part.noStroke();
+    part.texture(sprite);
+    part.normal(0, 0, 1);
+    part.vertex(-partSize/2, -partSize/2, 0, 0);
+    part.vertex(+partSize/2, -partSize/2, sprite.width, 0);
+    part.vertex(+partSize/2, +partSize/2, sprite.width, sprite.height);
+    part.vertex(-partSize/2, +partSize/2, 0, sprite.height);
+    part.endShape();    
+    particles.addChild(part);
+  }
+
+  partLifetime = npartTotal / npartPerFrame;
+  initVelocities();
+  initLifetimes(); 
+
+  // Writing to the depth buffer is disabled to avoid rendering
+  // artifacts due to the fact that the particles are semi-transparent
+  // but not z-sorted.
+  hint(DISABLE_DEPTH_MASK);
+} 
+
+void draw () {
+  background(0);
+
+  for (int n = 0; n < particles.getChildCount(); n++) {
+    PShape part = particles.getChild(n);
+
+    lifetimes[n]++;
+    if (lifetimes[n] == partLifetime) {
+      lifetimes[n] = 0;
+    }      
+
+    if (0 <= lifetimes[n]) {
+      float opacity = 1.0 - float(lifetimes[n]) / partLifetime;
+      part.setTint(color(255, opacity * 255));
+      
+      if (lifetimes[n] == 0) {
+        // Re-spawn dead particle
+        part.resetMatrix();
+        part.translate(mouseX, mouseY);
+        float angle = random(0, TWO_PI);
+        float s = random(0.5 * speed, 0.5 * speed);
+        velocities[n].x = s * cos(angle);
+        velocities[n].y = s * sin(angle);
+      } else {
+        part.translate(velocities[n].x, velocities[n].y);
+        velocities[n].y += gravity;
+      }
+    } else {
+      part.setTint(color(0));
+    }
+  }
+
+  shape(particles);
+  
+  fcount += 1;
+  int m = millis();
+  if (m - lastm > 1000 * fint) {
+    frate = float(fcount) / fint;
+    fcount = 0;
+    lastm = m;
+    println("fps: " + frate); 
+  } 
+}
+
+void initVelocities() {
+  velocities = new PVector[npartTotal];
+  for (int n = 0; n < velocities.length; n++) {
+    velocities[n] = new PVector();
+  }
+}
+
+void initLifetimes() {
+  // Initializing particles with negative lifetimes so they are added
+  // progressively into the screen during the first frames of the sketch   
+  lifetimes = new int[npartTotal];
+  int t = -1;
+  for (int n = 0; n < lifetimes.length; n++) {    
+    if (n % npartPerFrame == 0) {
+      t++;
+    }
+    lifetimes[n] = -t;
+  }
+} 

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Performance/Esfera/Esfera.pde

@@ -0,0 +1,90 @@
+/**
+ * Esfera
+ * by David Pena.  
+ * 
+ * Distribucion aleatoria uniforme sobre la superficie de una esfera. 
+ */
+
+int cuantos = 16000;
+Pelo[] lista ;
+float radio = 200;
+float rx = 0;
+float ry =0;
+
+void setup() {
+  size(1024, 768, P3D);
+
+  radio = height/3.5;
+
+  lista = new Pelo[cuantos];
+  for (int i = 0; i < lista.length; i++) {
+    lista[i] = new Pelo();
+  }
+  noiseDetail(3);
+}
+
+void draw() {
+  background(0);
+  
+  float rxp = (mouseX-(width/2)) * 0.005;
+  float ryp = (mouseY-(height/2)) * 0.005;
+  rx = rx*0.9 + rxp*0.1;
+  ry = ry*0.9 + ryp*0.1;
+
+  translate(width/2, height/2);
+  rotateY(rx);
+  rotateX(ry);
+  fill(0);
+  noStroke();
+  sphere(radio);
+
+  for (int i = 0; i < lista.length; i++) {
+    lista[i].dibujar();
+  }
+
+}
+
+
+class Pelo
+{
+  float z = random(-radio, radio);
+  float phi = random(TWO_PI);
+  float largo = random(1.15, 1.2);
+  float theta = asin(z/radio);
+
+  Pelo() { // what's wrong with a constructor here
+    z = random(-radio, radio);
+    phi = random(TWO_PI);
+    largo = random(1.15, 1.2);
+    theta = asin(z/radio);
+  }
+
+  void dibujar() {
+
+    float off = (noise(millis() * 0.0005, sin(phi))-0.5) * 0.3;
+    float offb = (noise(millis() * 0.0007, sin(z) * 0.01)-0.5) * 0.3;
+
+    float thetaff = theta+off;
+    float phff = phi+offb;
+    float x = radio * cos(theta) * cos(phi);
+    float y = radio * cos(theta) * sin(phi);
+    float z = radio * sin(theta);
+
+    float xo = radio * cos(thetaff) * cos(phff);
+    float yo = radio * cos(thetaff) * sin(phff);
+    float zo = radio * sin(thetaff);
+
+    float xb = xo * largo;
+    float yb = yo * largo;
+    float zb = zo * largo;
+
+    strokeWeight(1);
+    beginShape(LINES);
+    stroke(0);
+    vertex(x, y, z);
+    stroke(200, 150);
+    vertex(xb, yb, zb);
+    endShape();
+  }
+}
+

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Performance/LineRendering/LineRendering.pde

@@ -0,0 +1,24 @@
+
+public void setup() {
+  size(800, 600, P2D);  
+}
+  
+public void draw() {    
+  background(255);
+  stroke(0, 10);
+  for (int i = 0; i < 50000; i++) {
+    float x0 = random(width);
+    float y0 = random(height);
+    float z0 = random(-100, 100);
+    float x1 = random(width);
+    float y1 = random(height);
+    float z1 = random(-100, 100);    
+    
+    // purely 2D lines will trigger the GLU 
+    // tessellator to add accurate line caps,
+    // but performance will be substantially
+    // lower.
+    line(x0, y0, z0, x1, y1, z1);
+  }
+  if (frameCount % 10 == 0) println(frameRate);
+}

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Performance/QuadRendering/QuadRendering.pde

@@ -0,0 +1,17 @@
+
+public void setup() {
+  size(800, 600, P2D);
+  
+  noStroke();
+  fill(0, 1);  
+}
+  
+public void draw() {    
+  background(255);
+  for (int i = 0; i < 50000; i++) {
+    float x = random(width);
+    float y = random(height);
+    rect(x, y, 30, 30);
+  }
+  if (frameCount % 10 == 0) println(frameRate);
+}

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Performance/StaticParticlesImmediate/StaticParticlesImmediate.pde

@@ -0,0 +1,65 @@
+PImage sprite;  
+
+int npartTotal = 50000;
+float partSize = 20;
+
+PVector positions[];
+
+int fcount, lastm;
+float frate;
+int fint = 3;
+
+void setup() {
+  size(800, 600, P3D);
+  frameRate(60);
+  
+  sprite = loadImage("sprite.png");
+
+  initPositions();
+
+  // Writing to the depth buffer is disabled to avoid rendering
+  // artifacts due to the fact that the particles are semi-transparent
+  // but not z-sorted.
+  hint(DISABLE_DEPTH_MASK);
+} 
+
+void draw () {
+  background(0);
+
+  translate(width/2, height/2);
+  rotateY(frameCount * 0.01);
+ 
+  for (int n = 0; n < npartTotal; n++) {
+    drawParticle(positions[n]);
+  }
+  
+  fcount += 1;
+  int m = millis();
+  if (m - lastm > 1000 * fint) {
+    frate = float(fcount) / fint;
+    fcount = 0;
+    lastm = m;
+    println("fps: " + frate); 
+  }  
+}
+
+void drawParticle(PVector center) {
+  beginShape(QUAD);
+  noStroke();
+  tint(255);
+  texture(sprite);
+  normal(0, 0, 1);
+  vertex(center.x - partSize/2, center.y - partSize/2, center.z, 0, 0);
+  vertex(center.x + partSize/2, center.y - partSize/2, center.z, sprite.width, 0);
+  vertex(center.x + partSize/2, center.y + partSize/2, center.z, sprite.width, sprite.height);
+  vertex(center.x - partSize/2, center.y + partSize/2, center.z, 0, sprite.height);                
+  endShape();  
+}
+
+void initPositions() {
+  positions = new PVector[npartTotal];
+  for (int n = 0; n < positions.length; n++) {
+    positions[n] = new PVector(random(-500, +500), random(-500, +500), random(-500, +500));
+  }  
+}
+

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Performance/StaticParticlesRetained/StaticParticlesRetained.pde

@@ -0,0 +1,60 @@
+PShape particles;
+PImage sprite;  
+
+int npartTotal = 50000;
+float partSize = 20;
+
+int fcount, lastm;
+float frate;
+int fint = 3;
+
+void setup() {
+  size(800, 600, P3D);
+  frameRate(60);
+
+  particles = createShape(PShape.GROUP);
+  sprite = loadImage("sprite.png");
+
+  for (int n = 0; n < npartTotal; n++) {
+    float cx = random(-500, +500);
+    float cy = random(-500, +500); 
+    float cz = random(-500, +500);
+    
+    PShape part = createShape();
+    part.beginShape(QUAD);
+    part.noStroke();
+    part.tint(255);
+    part.texture(sprite);
+    part.normal(0, 0, 1);
+    part.vertex(cx - partSize/2, cy - partSize/2, cz, 0, 0);
+    part.vertex(cx + partSize/2, cy - partSize/2, cz, sprite.width, 0);
+    part.vertex(cx + partSize/2, cy + partSize/2, cz, sprite.width, sprite.height);
+    part.vertex(cx - partSize/2, cy + partSize/2, cz, 0, sprite.height);    
+    part.endShape();    
+    particles.addChild(part);
+  }
+
+  // Writing to the depth buffer is disabled to avoid rendering
+  // artifacts due to the fact that the particles are semi-transparent
+  // but not z-sorted.
+  hint(DISABLE_DEPTH_MASK);
+} 
+
+void draw () {
+  background(0);
+
+  translate(width/2, height/2);
+  rotateY(frameCount * 0.01);
+
+  shape(particles);
+  
+  fcount += 1;
+  int m = millis();
+  if (m - lastm > 1000 * fint) {
+    frate = float(fcount) / fint;
+    fcount = 0;
+    lastm = m;
+    println("fps: " + frate); 
+  }  
+}
+

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Performance/TextRendering/TextRendering.pde

@@ -0,0 +1,15 @@
+
+public void setup() {
+  size(800, 600, P2D);
+  fill(0);
+}
+  
+public void draw() {    
+  background(255);
+  for (int i = 0; i < 10000; i++) {
+    float x = random(width);
+    float y = random(height);
+    text("HELLO", x, y);
+  }
+  if (frameCount % 10 == 0) println(frameRate);
+}

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Tests/MultipleWindows/Arcball.pde

@@ -0,0 +1,194 @@
+// Ariel and V3ga's arcball class with a couple tiny mods by Robert Hodgin
+
+class Arcball {
+  PApplet parent;
+  float center_x, center_y, radius;
+  Vec3 v_down, v_drag;
+  Quat q_now, q_down, q_drag;
+  Vec3[] axisSet;
+  int axis;
+  float mxv, myv;
+  float x, y;
+  
+  Arcball(PApplet parent, float radius){
+    this.parent = parent;
+    this.radius = radius;
+
+    v_down = new Vec3();
+    v_drag = new Vec3();
+
+    q_now = new Quat();
+    q_down = new Quat();
+    q_drag = new Quat();
+
+    axisSet = new Vec3[] {new Vec3(1.0f, 0.0f, 0.0f), new Vec3(0.0f, 1.0f, 0.0f), new Vec3(0.0f, 0.0f, 1.0f)};
+    axis = -1;  // no constraints...    
+  }
+
+  void mousePressed(){
+    v_down = mouse_to_sphere(parent.mouseX, parent.mouseY);
+    q_down.set(q_now);
+    q_drag.reset();
+  }
+
+  void mouseDragged(){
+    v_drag = mouse_to_sphere(parent.mouseX, parent.mouseY);
+    q_drag.set(Vec3.dot(v_down, v_drag), Vec3.cross(v_down, v_drag));
+  }
+
+  void run(){
+    center_x = parent.width/2.0;
+    center_y = parent.height/2.0;
+    
+    q_now = Quat.mul(q_drag, q_down);
+    parent.translate(center_x, center_y);
+    applyQuat2Matrix(q_now);
+    
+    x += mxv;
+    y += myv;
+    mxv -= mxv * .01;
+    myv -= myv * .01;
+  }
+  
+  Vec3 mouse_to_sphere(float x, float y){
+    Vec3 v = new Vec3();
+    v.x = (x - center_x) / radius;
+    v.y = (y - center_y) / radius;
+
+    float mag = v.x * v.x + v.y * v.y;
+    if (mag > 1.0f){
+      v.normalize();
+    } else {
+      v.z = sqrt(1.0f - mag);
+    }
+
+    return (axis == -1) ? v : constrain_vector(v, axisSet[axis]);
+  }
+
+  Vec3 constrain_vector(Vec3 vector, Vec3 axis){
+    Vec3 res = new Vec3();
+    res.sub(vector, Vec3.mul(axis, Vec3.dot(axis, vector)));
+    res.normalize();
+    return res;
+  }
+
+  void applyQuat2Matrix(Quat q){
+    // instead of transforming q into a matrix and applying it...
+
+    float[] aa = q.getValue();
+    parent.rotate(aa[0], aa[1], aa[2], aa[3]);
+  }
+}
+
+static class Vec3{
+  float x, y, z;
+
+  Vec3(){
+  }
+
+  Vec3(float x, float y, float z){
+    this.x = x;
+    this.y = y;
+    this.z = z;
+  }
+
+  void normalize(){
+    float length = length();
+    x /= length;
+    y /= length;
+    z /= length;
+  }
+
+  float length(){
+    return (float) Math.sqrt(x * x + y * y + z * z);
+  }
+
+  static Vec3 cross(Vec3 v1, Vec3 v2){
+    Vec3 res = new Vec3();
+    res.x = v1.y * v2.z - v1.z * v2.y;
+    res.y = v1.z * v2.x - v1.x * v2.z;
+    res.z = v1.x * v2.y - v1.y * v2.x;
+    return res;
+  }
+
+  static float dot(Vec3 v1, Vec3 v2){
+    return v1.x * v2.x + v1.y * v2.y + v1.z * v2.z;
+  }
+  
+  static Vec3 mul(Vec3 v, float d){
+    Vec3 res = new Vec3();
+    res.x = v.x * d;
+    res.y = v.y * d;
+    res.z = v.z * d;
+    return res;
+  }
+
+  void sub(Vec3 v1, Vec3 v2){
+    x = v1.x - v2.x;
+    y = v1.y - v2.y;
+    z = v1.z - v2.z;
+  }
+}
+
+static class Quat{
+  float w, x, y, z;
+
+  Quat(){
+    reset();
+  }
+
+  Quat(float w, float x, float y, float z){
+    this.w = w;
+    this.x = x;
+    this.y = y;
+    this.z = z;
+  }
+
+  void reset(){
+    w = 1.0f;
+    x = 0.0f;
+    y = 0.0f;
+    z = 0.0f;
+  }
+
+  void set(float w, Vec3 v){
+    this.w = w;
+    x = v.x;
+    y = v.y;
+    z = v.z;
+  }
+
+  void set(Quat q){
+    w = q.w;
+    x = q.x;
+    y = q.y;
+    z = q.z;
+  }
+
+  static Quat mul(Quat q1, Quat q2){
+    Quat res = new Quat();
+    res.w = q1.w * q2.w - q1.x * q2.x - q1.y * q2.y - q1.z * q2.z;
+    res.x = q1.w * q2.x + q1.x * q2.w + q1.y * q2.z - q1.z * q2.y;
+    res.y = q1.w * q2.y + q1.y * q2.w + q1.z * q2.x - q1.x * q2.z;
+    res.z = q1.w * q2.z + q1.z * q2.w + q1.x * q2.y - q1.y * q2.x;
+    return res;
+  }
+  
+  float[] getValue(){
+    // transforming this quat into an angle and an axis vector...
+
+    float[] res = new float[4];
+
+    float sa = (float) Math.sqrt(1.0f - w * w);
+    if (sa < EPSILON){
+      sa = 1.0f;
+    }
+
+    res[0] = (float) Math.acos(w) * 2.0f;
+    res[1] = x / sa;
+    res[2] = y / sa;
+    res[3] = z / sa;
+
+    return res;
+  }
+}

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Tests/MultipleWindows/MultipleWindows.pde

@@ -0,0 +1,90 @@
+// Based on code by GeneKao (https://github.com/GeneKao)
+
+ChildApplet child;
+boolean mousePressedOnParent = false;
+Arcball arcball, arcball2;  
+
+void settings() {
+  size(320, 240, P3D);
+  smooth();
+}
+
+void setup() {
+  surface.setTitle("Main sketch");
+  arcball = new Arcball(this, 300);
+  child = new ChildApplet();
+}
+
+void draw() {
+  background(250);
+  arcball.run();
+  if (mousePressed) {
+    fill(0);
+    text("Mouse pressed on parent.", 10, 10);
+    fill(0, 240, 0);
+    ellipse(mouseX, mouseY, 60, 60);
+    mousePressedOnParent = true;
+  } else {
+    fill(20);
+    ellipse(width/2, height/2, 60, 60);
+    mousePressedOnParent = false;
+  }
+  box(100);
+  if (child.mousePressed) {
+    text("Mouse pressed on child.", 10, 30);
+  }
+}
+
+void mousePressed() {
+  arcball.mousePressed();
+}
+
+void mouseDragged() {
+  arcball.mouseDragged();
+}
+
+class ChildApplet extends PApplet {
+  //JFrame frame;
+
+  public ChildApplet() {
+    super();
+    PApplet.runSketch(new String[]{this.getClass().getName()}, this);
+  }
+
+  public void settings() {
+    size(400, 400, P3D);
+    smooth();
+  }
+  public void setup() { 
+    surface.setTitle("Child sketch");
+    arcball2 = new Arcball(this, 300);
+  }
+
+  public void draw() {
+    background(0);
+    arcball2.run();
+    if (mousePressed) {
+      fill(240, 0, 0);
+      ellipse(mouseX, mouseY, 20, 20);
+      fill(255);
+      text("Mouse pressed on child.", 10, 30);
+    } else {
+      fill(255);
+      ellipse(width/2, height/2, 20, 20);
+    }
+
+    box(100, 200, 100);
+    if (mousePressedOnParent) {
+      fill(255);
+      text("Mouse pressed on parent", 20, 20);
+    }
+  }
+
+  public void mousePressed() {
+    arcball2.mousePressed();
+  }
+
+  public void mouseDragged() {
+    arcball2.mouseDragged();
+  }
+}

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Tests/NoBackgroundTest/NoBackgroundTest.pde

@@ -0,0 +1,10 @@
+void setup() {
+  size(400, 400, P2D); 
+  background(255, 0, 0);
+  fill(255, 150);
+}
+
+void draw() {
+  ellipse(mouseX, mouseY, 100, 100);  
+}
+

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Tests/OffscreenTest/OffscreenTest.pde

@@ -0,0 +1,19 @@
+PGraphics pg;
+
+void setup() {
+  size(400, 400, P3D);
+
+  pg = createGraphics(400, 400, P3D);
+  pg.smooth(4);
+}
+
+void draw() {
+  background(0);
+
+  pg.beginDraw();
+  pg.background(255, 0, 0);
+  pg.ellipse(mouseX, mouseY, 100, 100);
+  pg.endDraw();
+
+  image(pg, 0, 0, 400, 400);
+}

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Tests/RedrawTest/RedrawTest.pde

@@ -0,0 +1,14 @@
+void setup() {
+  size(400, 400, P3D);  
+  noLoop();
+}
+
+void draw() {
+  background(255, 0, 0);
+  ellipse(mouseX, mouseY, 100, 50);
+  println("draw");  
+}
+
+void keyPressed() {
+  redraw();
+}

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Tests/ResizeTest/ResizeTest.pde

@@ -0,0 +1,10 @@
+void setup() {
+  size(400, 400, P3D);
+  surface.setResizable(true);
+}
+
+void draw() {
+  background(255, 0, 0);
+  ellipse(width/2, height/2, 100, 50);  
+}
+

Java/Processing/processing-3.3.6/modes/java/examples/Demos/Tests/SpecsTest/SpecsTest.pde

@@ -0,0 +1,7 @@
+size(100, 100, P3D);
+PGraphicsOpenGL pg = (PGraphicsOpenGL)g;
+println(PGraphicsOpenGL.OPENGL_VENDOR);
+println(PGraphicsOpenGL.OPENGL_RENDERER);
+println(PGraphicsOpenGL.OPENGL_VERSION);
+println(PGraphicsOpenGL.GLSL_VERSION);
+println(PGraphicsOpenGL.OPENGL_EXTENSIONS);