Initial Commit

Java/Processing/processing-3.3.6/modes/java/examples/Topics/Shaders/SepBlur/SepBlur.pde

@@ -0,0 +1,68 @@
+/**
+ * Separate Blur Shader
+ * 
+ * This blur shader works by applying two successive passes, one horizontal
+ * and the other vertical.
+ * 
+ * Press the mouse to switch between the custom and default shader.
+ */
+
+PShader blur;
+PGraphics src;
+PGraphics pass1, pass2;
+
+void setup() {
+  size(640, 360, P2D);
+  
+  blur = loadShader("blur.glsl");
+  blur.set("blurSize", 9);
+  blur.set("sigma", 5.0f);  
+  
+  src = createGraphics(width, height, P2D); 
+  
+  pass1 = createGraphics(width, height, P2D);
+  pass1.noSmooth();  
+  
+  pass2 = createGraphics(width, height, P2D);
+  pass2.noSmooth();
+}
+
+void draw() {
+  src.beginDraw();
+  src.background(0);
+  src.fill(255);
+  src.ellipse(width/2, height/2, 100, 100);
+  src.endDraw();
+    
+  // Applying the blur shader along the vertical direction   
+  blur.set("horizontalPass", 0);
+  pass1.beginDraw();            
+  pass1.shader(blur);  
+  pass1.image(src, 0, 0);
+  pass1.endDraw();
+  
+  // Applying the blur shader along the horizontal direction      
+  blur.set("horizontalPass", 1);
+  pass2.beginDraw();            
+  pass2.shader(blur);  
+  pass2.image(pass1, 0, 0);
+  pass2.endDraw();    
+        
+  image(pass2, 0, 0);   
+}
+
+void keyPressed() {
+  if (key == '9') {
+    blur.set("blurSize", 9);
+    blur.set("sigma", 5.0);
+  } else if (key == '7') {
+    blur.set("blurSize", 7);
+    blur.set("sigma", 3.0);
+  } else if (key == '5') {
+    blur.set("blurSize", 5);
+    blur.set("sigma", 2.0);  
+  } else if (key == '3') {
+    blur.set("blurSize", 5);
+    blur.set("sigma", 1.0);  
+  }  
+} 

Java/Processing/processing-3.3.6/modes/java/examples/Topics/Shaders/SepBlur/data/blur.glsl

@@ -0,0 +1,59 @@
+// Adapted from:
+// http://callumhay.blogspot.com/2010/09/gaussian-blur-shader-glsl.html
+
+#ifdef GL_ES
+precision mediump float;
+precision mediump int;
+#endif
+
+#define PROCESSING_TEXTURE_SHADER
+
+uniform sampler2D texture;
+
+// The inverse of the texture dimensions along X and Y
+uniform vec2 texOffset;
+
+varying vec4 vertColor;
+varying vec4 vertTexCoord;
+
+uniform int blurSize;       
+uniform int horizontalPass; // 0 or 1 to indicate vertical or horizontal pass
+uniform float sigma;        // The sigma value for the gaussian function: higher value means more blur
+                            // A good value for 9x9 is around 3 to 5
+                            // A good value for 7x7 is around 2.5 to 4
+                            // A good value for 5x5 is around 2 to 3.5
+                            // ... play around with this based on what you need :)
+
+const float pi = 3.14159265;
+
+void main() {  
+  float numBlurPixelsPerSide = float(blurSize / 2); 
+  
+  vec2 blurMultiplyVec = 0 < horizontalPass ? vec2(1.0, 0.0) : vec2(0.0, 1.0);
+
+  // Incremental Gaussian Coefficent Calculation (See GPU Gems 3 pp. 877 - 889)
+  vec3 incrementalGaussian;
+  incrementalGaussian.x = 1.0 / (sqrt(2.0 * pi) * sigma);
+  incrementalGaussian.y = exp(-0.5 / (sigma * sigma));
+  incrementalGaussian.z = incrementalGaussian.y * incrementalGaussian.y;
+
+  vec4 avgValue = vec4(0.0, 0.0, 0.0, 0.0);
+  float coefficientSum = 0.0;
+
+  // Take the central sample first...
+  avgValue += texture2D(texture, vertTexCoord.st) * incrementalGaussian.x;
+  coefficientSum += incrementalGaussian.x;
+  incrementalGaussian.xy *= incrementalGaussian.yz;
+
+  // Go through the remaining 8 vertical samples (4 on each side of the center)
+  for (float i = 1.0; i <= numBlurPixelsPerSide; i++) { 
+    avgValue += texture2D(texture, vertTexCoord.st - i * texOffset * 
+                          blurMultiplyVec) * incrementalGaussian.x;         
+    avgValue += texture2D(texture, vertTexCoord.st + i * texOffset * 
+                          blurMultiplyVec) * incrementalGaussian.x;         
+    coefficientSum += 2.0 * incrementalGaussian.x;
+    incrementalGaussian.xy *= incrementalGaussian.yz;
+  }
+
+  gl_FragColor = avgValue / coefficientSum;
+}